reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th39:
  seq is convergent implies lim(r*seq)=r*(lim seq)
proof
A1: now
    assume
A2: r=0;
    let q such that
A3: 0<q;
     reconsider k=0 as Nat;
    take k;
    let m such that
    k<=m;
    r*(lim seq)=0.TOP-REAL N by A2,RLVECT_1:10;
    then |.((r*seq).m)-r*(lim seq).|=|.0 * seq.m-0.TOP-REAL N.| by A2,Th5
      .=|.0.TOP-REAL N-0 * seq.m.| by Th27
      .=|.0.TOP-REAL N+-0 * seq.m.|
      .=|.-0 * seq.m.| by RLVECT_1:4
      .=|.0 * seq.m.| by EUCLID:71
      .=|.0.TOP-REAL N.| by RLVECT_1:10
      .=0 by Th23;
    hence |.((r*seq).m)-r*(lim seq).|<q by A3;
  end;
  assume
A4: seq is convergent;
A5: now
A6: 0/|.r.|=0;
    assume
A7: r<>0;
    then
A8: 0<|.r.| by COMPLEX1:47;
    let q;
    assume 0<q;
    then 0<q/|.r.| by A8,A6,XREAL_1:74;
    then consider n1 such that
A9: for m st n1<=m holds |.seq.m-(lim seq).|<q/|.r.| by A4,Def9;
    take k=n1;
    let m;
    assume k<=m;
    then
A10: |.seq.m-(lim seq).|<q/|.r.| by A9;
A11: 0<>|.r.| by A7,COMPLEX1:47;
A12: |.r.|*(q/|.r.|)=|.r.|*(|.r.|"*q) by XCMPLX_0:def 9
      .=|.r.|*|.r.|"*q
      .=1*q by A11,XCMPLX_0:def 7
      .=q;
    |.((r*seq).m)-r*(lim seq).|=|.r*seq.m-r*(lim seq).| by Th5
      .=|.r*(seq.m-(lim seq)).| by RLVECT_1:34
      .=|.r.|*|.seq.m-(lim seq).| by Th7;
    hence |.((r*seq).m)-r*(lim seq).|<q by A8,A10,A12,XREAL_1:68;
  end;
  r*seq is convergent by A4,Th38;
  hence thesis by A1,A5,Def9;
end;
