reserve AP for AffinPlane;
reserve a,a9,b,b9,c,c9,d,x,y,o,p,q for Element of AP;
reserve A,C,D9,M,N,P for Subset of AP;

theorem
  AP is Desarguesian implies AP is satisfying_DES1
proof
  assume
A1: AP is Desarguesian;
  let A,P,C,o,a,a9,b,b9,c,c9,p,q;
  assume that
A2: A is being_line and
A3: P is being_line and
A4: C is being_line and
A5: P<>A and
A6: P<>C and
A7: A<>C and
A8: o in A and
A9: a in A and
A10: a9 in A and
A11: o in P and
A12: b in P and
A13: b9 in P and
A14: o in C and
A15: c in C and
A16: c9 in C and
A17: o<>a and
A18: o<>b and
A19: o<>c and
  p<>q and
A20: not LIN b,a,c and
A21: not LIN b9,a9,c9 and
A22: a<>a9 and
A23: LIN b,a,p and
A24: LIN b9,a9,p and
A25: LIN b,c,q and
A26: LIN b9,c9,q and
A27: a,c // a9,c9;
  set D=Line(b,c);
  b<>c by A20,AFF_1:7;
  then D is being_line by AFF_1:def 3;
  then consider D9 such that
A28: c9 in D9 and
A29: D // D9 by AFF_1:49;
A30: D9 is being_line by A29,AFF_1:36;
  set M=Line(b9,c9);
A31: q in M by A26,AFF_1:def 2;
A32: b in D by AFF_1:15;
A33: c in D by AFF_1:15;
  not D9 // P
  proof
    assume D9 // P;
    then D // P by A29,AFF_1:44;
    then c in P by A12,A32,A33,AFF_1:45;
    hence contradiction by A3,A4,A6,A11,A14,A15,A19,AFF_1:18;
  end;
  then consider d such that
A34: d in D9 and
A35: d in P by A3,A30,AFF_1:58;
A36: q in D by A25,AFF_1:def 2;
  then
A37: d,c9 // b,q by A32,A28,A29,A34,AFF_1:39;
A38: a<>b & b,a // b,p by A20,A23,AFF_1:7,def 1;
A39: c,a // c9,a9 by A27,AFF_1:4;
  c,b // c9,d by A32,A33,A28,A29,A34,AFF_1:39;
  then b,a // d,a9 by A1,A2,A3,A4,A6,A7,A8,A9,A10,A11,A12,A14,A15,A16,A17,A18
,A19,A35,A39;
  then
A40: d,a9 // b,p by A38,AFF_1:5;
  set K=Line(b9,a9);
A41: b9 in K & p in K by A24,AFF_1:15,def 2;
A42: a9<>b9 by A21,AFF_1:7;
  then
A43: K is being_line by AFF_1:def 3;
A44: b9 in M by AFF_1:15;
A45: c9 in M by AFF_1:15;
A46: b9<>c9 by A21,AFF_1:7;
  then
A47: M is being_line by AFF_1:def 3;
A48: not LIN o,a,c
  proof
    assume LIN o,a,c;
    then c in A by A2,A8,A9,A17,AFF_1:25;
    hence contradiction by A2,A4,A7,A8,A14,A15,A19,AFF_1:18;
  end;
A49: c <>c9
  proof
    assume c =c9;
    then
A50: c,a // c,a9 by A27,AFF_1:4;
    LIN o,a,a9 & not LIN o,c,a by A2,A8,A9,A10,A48,AFF_1:6,21;
    hence contradiction by A22,A50,AFF_1:14;
  end;
A51: d<>b9
  proof
    assume d=b9;
    then M=D9 by A46,A47,A44,A45,A28,A30,A34,AFF_1:18;
    then D=M by A31,A36,A29,AFF_1:45;
    then LIN c,c9,b by A47,A45,A32,A33,AFF_1:21;
    then b in C by A4,A15,A16,A49,AFF_1:25;
    hence contradiction by A3,A4,A6,A11,A12,A14,A18,AFF_1:18;
  end;
A52: a9<>c9 by A21,AFF_1:7;
A53: o<>a9 by A4,A14,A15,A16,A27,A52,A48,AFF_1:21,55;
  o<>c9
  proof
A54: not LIN o,c,a by A48,AFF_1:6;
    assume
A55: o=c9;
    LIN o,a,a9 & c,a // c9,a9 by A2,A8,A9,A10,A27,AFF_1:4,21;
    hence contradiction by A53,A55,A54,AFF_1:55;
  end;
  then
A56: M<>P by A3,A4,A6,A11,A14,A16,A45,AFF_1:18;
A57: a9 in K by AFF_1:15;
  then K<>P by A2,A3,A5,A8,A10,A11,A53,AFF_1:18;
  then a9,c9 // p,q by A1,A3,A12,A13,A42,A46,A43,A47,A57,A41,A44,A45,A31,A56
,A35,A51,A40,A37;
  hence thesis by A27,A52,AFF_1:5;
end;
