
theorem Th3:
  for X being non empty finite set, x being Element of X ex A being
  non empty Subset of X st x = meet A & for s being set st s in A holds s
  is_/\-irreducible_in X
proof
  let X be non empty finite set, x be Element of X;
  defpred P[set] means ex S being non empty Subset of X st $1 = meet S & for s
  being set st s in S holds s is_/\-irreducible_in X;
A1: now
    let x, y be set such that
    x in X and
    y in X and
A2: P[x] and
A3: P[y];
    consider Sy being non empty Subset of X such that
A4: y = meet Sy and
A5: for s being set st s in Sy holds s is_/\-irreducible_in X by A3;
    consider Sx being non empty Subset of X such that
A6: x = meet Sx and
A7: for s being set st s in Sx holds s is_/\-irreducible_in X by A2;
    reconsider S = Sx\/Sy as non empty Subset of X;
    now
      take S;
      thus x /\ y = meet S by A6,A4,SETFAM_1:9;
      let s be set;
      assume
A8:   s in S;
      per cases by A8,XBOOLE_0:def 3;
      suppose
        s in Sx;
        hence s is_/\-irreducible_in X by A7;
      end;
      suppose
        s in Sy;
        hence s is_/\-irreducible_in X by A5;
      end;
    end;
    hence P[x /\ y];
  end;
A9: now
    let x be set;
    assume
A10: x is_/\-irreducible_in X;
    thus P[x]
    proof
      x in X by A10;
      then reconsider S = {x} as non empty Subset of X by ZFMISC_1:31;
      take S;
      thus x = meet S by SETFAM_1:10;
      let s be set;
      assume s in S;
      hence thesis by A10,TARSKI:def 1;
    end;
  end;
  for x being set st x in X holds P[x] from FinIntersect(A9,A1);
  hence thesis;
end;
