reserve X for RealUnitarySpace;
reserve x for Point of X;
reserve i, n for Nat;

theorem Th3:
  for Y be Subset of X st Y is summable_set holds Y is weakly_summable_set
proof
  let Y be Subset of X;
  assume Y is summable_set;
  then consider x such that
A1: for e be Real st 0 < e ex Y0 be finite Subset of X st Y0 is non
empty & Y0 c= Y & for Y1 be finite Subset of X st Y0 c= Y1 & Y1 c= Y holds ||.x
  - setsum(Y1).|| < e;
  now
    let L be linear-Functional of X;
    assume L is Lipschitzian;
    then consider K be Real such that
A2: 0 < K and
A3: for x holds |.L.x.| <= K * ||.x.||;
    now
      let e1 be Real such that
A4:   0 < e1;
      set e = e1/K;
      consider Y0 be finite Subset of X such that
A5:   Y0 is non empty & Y0 c= Y and
A6:   for Y1 be finite Subset of X st Y0 c= Y1 & Y1 c=Y holds ||.x -
      setsum(Y1).|| < e by A1,A2,A4,XREAL_1:139;
A7:   e * K = e1 by A2,XCMPLX_1:87;
      now
        let Y1 be finite Subset of X;
        assume Y0 c= Y1 & Y1 c=Y;
        then K * ||.x - setsum(Y1).|| < e1 by A2,A7,A6,XREAL_1:68;
        then
        |.L.(x-setsum(Y1)).| + K*||.(x-setsum(Y1)).|| < K*||.(x-setsum(
        Y1)).|| + e1 by A3,XREAL_1:8;
        then
        |.L.(x-setsum(Y1)).| + K*||.(x-setsum(Y1)).|| - K*||.(x-setsum(
Y1)).|| < K*||.(x-setsum(Y1)).|| + e1 - K*||.(x-setsum(Y1)).|| by XREAL_1:14;
        hence |.L.(x-setsum(Y1)).| < e1;
      end;
      hence ex Y0 be finite Subset of X st Y0 is non empty & Y0 c= Y & for Y1
be finite Subset of X st Y0 c= Y1 & Y1 c=Y holds |.L.(x-setsum(Y1)).| < e1
by A5;
    end;
    hence for e1 be Real st 0 < e1
       ex Y0 be finite Subset of X st Y0 is non
empty & Y0 c= Y & for Y1 be finite Subset of X st Y0 c= Y1 & Y1 c=Y holds |.
    L.(x-setsum(Y1)).| < e1;
  end;
  hence thesis;
end;
