reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem Th3:
  Partial_Product(JSum(Prob*A)).n = exp_R.(-Partial_Sums(Prob*A).n)
proof
 defpred J[Nat] means
  exp_R.(-Partial_Sums(Prob*A).$1) = Partial_Product(JSum(Prob*A)).$1;
 A1: exp_R.(-Partial_Sums(Prob*A).0) = exp_R.(-(Prob*A).0)
  by SERIES_1:def 1;
 Partial_Product(JSum(Prob*A)).0 = (JSum(Prob*A)).0 by SERIES_3:def 1; then
 Partial_Product(JSum(Prob*A)).0 = Sum( (-(Prob*A).0) rExpSeq) by Def1; then
 A2: J[0] by A1,SIN_COS:def 22;
 A3: for k being Nat st J[k] holds J[k+1]
 proof
  let k be Nat;
  assume A4: J[k];
   Partial_Product(JSum(Prob*A)).(k+1) =
   Partial_Product(JSum(Prob*A)).k * (JSum(Prob*A)).(k+1)
   by SERIES_3:def 1; then
  A6: Partial_Product(JSum(Prob*A)).(k+1) =
   exp_R.(-Partial_Sums(Prob*A).k) *
    Sum( (-(Prob*A).(k+1)) rExpSeq) by A4,Def1;
  A7: exp_R(-Partial_Sums(Prob*A).k) * exp_R(-(Prob*A).(k+1)) =
    exp_R(-Partial_Sums(Prob*A).k + (-(Prob*A).(k+1))) by SIN_COS:50;
  - (Partial_Sums(Prob*A).k + (Prob*A).(k+1)) =
  - Partial_Sums(Prob*A).(k+1) by SERIES_1:def 1;
 hence thesis by A7,A6,SIN_COS:def 22;
 end;
 for k being Nat holds J[k] from NAT_1:sch 2(A2,A3);
 hence thesis;
 end;
