reserve n for Nat,
        p,q,u,w for Point of TOP-REAL n,
        S for Subset of TOP-REAL n,
        A, B for convex Subset of TOP-REAL n,
        r for Real;

theorem
  for S st p in S & p <> q & S/\halfline(p,q) is bounded
  ex w st w in (Fr S)/\halfline(p,q) &
          (for u st u in S/\halfline(p,q) holds |.p-u.| <= |.p-w.|) &
          for r st r > 0 ex u st u in S/\halfline(p,q) & |.w-u.| < r
proof
  set T=TOP-REAL n,E=Euclid n;
  let A be Subset of T such that
A1: p in A & p<>q & A/\halfline(p,q) is bounded;
  consider W be Point of E such that
A2: W in (Fr A)/\halfline(p,q) and
A3: for u,P be Point of E st P=p & u in A/\halfline(p,q)
      holds dist(P,u)<= dist(P,W) and
A4: for r st r>0 ex u be Point of E st u in A/\halfline(p,q)
& dist(W,u)<r by A1,Lm3;
  reconsider w=W as Point of T by EUCLID:67;
  take w;
  thus w in (Fr A)/\halfline(p,q) by A2;
  reconsider P=p as Point of E by EUCLID:67;
  hereby let u be Point of T such that
A5:   u in A/\halfline(p,q);
    reconsider U=u as Point of E by EUCLID:67;
A6:   dist(P,U)=|.p-u.| by SPPOL_1:39;
    dist(P,U)<=dist(P,W) by A3,A5;
    hence |.p-u.|<=|.p-w.| by A6,SPPOL_1:39;
  end;
  let r be Real;
  assume r>0;
  then consider U be Point of E such that
A7: U in A/\halfline(p,q) & dist(W,U)<r by A4;
  reconsider u=U as Point of T by EUCLID:67;
  dist(W,U)=|.w-u.| by SPPOL_1:39;
  hence thesis by A7;
 end;
