reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  G={B,C,D} & B<>C & C<>D & D<>B implies '/\' G = B '/\' C '/\' D
proof
  assume that
A1: G={B,C,D} and
A2: B<>C and
A3: C<>D and
A4: D<>B;
A5: B '/\' C '/\' D c= '/\' G
  proof
    let x be object;
     reconsider xx=x as set by TARSKI:1;
    assume
A6: x in B '/\' C '/\' D;
    then
A7: x<>{} by EQREL_1:def 4;
    x in INTERSECTION(B '/\' C,D) \ {{}} by A6,PARTIT1:def 4;
    then consider a,d being set such that
A8: a in B '/\' C and
A9: d in D and
A10: x = a /\ d by SETFAM_1:def 5;
    a in INTERSECTION(B,C) \ {{}} by A8,PARTIT1:def 4;
    then consider b,c being set such that
A11: b in B and
A12: c in C and
A13: a = b /\ c by SETFAM_1:def 5;
    set h = (B,C,D) --> (b,c,d);
A14: rng h = {h.B,h.C,h.D} by Lm2
      .= {h.D,h.B,h.C} by ENUMSET1:59;
A15: h.D = d by FUNCT_7:94;
    rng h c= bool Y
    proof
      let t be object;
      assume
A16:  t in rng h;
      now
        per cases by A14,A16,ENUMSET1:def 1;
        case
          t=h.D;
          hence thesis by A9,A15;
        end;
        case
          t=h.B;
          then t=b by A2,A4,FUNCT_4:134;
          hence thesis by A11;
        end;
        case
          t=h.C;
          then t=c by A3,Lm1;
          hence thesis by A12;
        end;
      end;
      hence thesis;
    end;
    then reconsider F=rng h as Subset-Family of Y;
A17: h.C = c by A3,Lm1;
A18: for p being set st p in G holds h.p in p
    proof
      let p be set;
      assume
A19:  p in G;
      now
        per cases by A1,A19,ENUMSET1:def 1;
        case
          p=D;
          hence thesis by A9,FUNCT_7:94;
        end;
        case
          p=B;
          hence thesis by A2,A4,A11,FUNCT_4:134;
        end;
        case
          p=C;
          hence thesis by A3,A12,Lm1;
        end;
      end;
      hence thesis;
    end;
A20: h.B = b by A2,A4,FUNCT_4:134;
A21: xx c= Intersect F
    proof
      let u be object;
      assume
A22:  u in xx;
      for y be set holds y in F implies u in y
      proof
        let y be set;
        assume
A23:    y in F;
        now
          per cases by A14,A23,ENUMSET1:def 1;
          case
            y=h.D;
            hence thesis by A10,A15,A22,XBOOLE_0:def 4;
          end;
          case
A24:        y=h.B;
            u in b /\ (c /\ d) by A10,A13,A22,XBOOLE_1:16;
            hence thesis by A20,A24,XBOOLE_0:def 4;
          end;
          case
A25:        y=h.C;
            u in c /\ (b /\ d) by A10,A13,A22,XBOOLE_1:16;
            hence thesis by A17,A25,XBOOLE_0:def 4;
          end;
        end;
        hence thesis;
      end;
      then u in meet F by A14,SETFAM_1:def 1;
      hence thesis by A14,SETFAM_1:def 9;
    end;
A26: dom h = {B,C,D} by FUNCT_4:128;
    then D in dom h by ENUMSET1:def 1;
    then
A27: rng h <> {} by FUNCT_1:3;
    Intersect F c= xx
    proof
      let t be object;
      assume t in Intersect F;
      then
A28:  t in meet (rng h) by A27,SETFAM_1:def 9;
      h.C in {h.D,h.B,h.C} by ENUMSET1:def 1;
      then t in h.C by A14,A28,SETFAM_1:def 1;
      then
A29:  t in c by A3,Lm1;
      h.B in {h.D,h.B,h.C} by ENUMSET1:def 1;
      then t in h.B by A14,A28,SETFAM_1:def 1;
      then t in b by A2,A4,FUNCT_4:134;
      then
A30:  t in b /\ c by A29,XBOOLE_0:def 4;
      h.D in {h.D,h.B,h.C} by ENUMSET1:def 1;
      then t in h.D by A14,A28,SETFAM_1:def 1;
      hence thesis by A10,A13,A15,A30,XBOOLE_0:def 4;
    end;
    then x = Intersect F by A21,XBOOLE_0:def 10;
    hence thesis by A1,A26,A18,A7,BVFUNC_2:def 1;
  end;
  '/\' G c= B '/\' C '/\' D
  proof
    let x be object;
     reconsider xx=x as set by TARSKI:1;
    assume x in '/\' G;
    then consider h being Function, F being Subset-Family of Y such that
A31: dom h=G and
A32: rng h = F and
A33: for d being set st d in G holds h.d in d and
A34: x=Intersect F and
A35: x<>{} by BVFUNC_2:def 1;
    D in dom h by A1,A31,ENUMSET1:def 1;
    then
A36: h.D in rng h by FUNCT_1:def 3;
    set m=h.B /\ h.C;
    B in dom h by A1,A31,ENUMSET1:def 1;
    then
A37: h.B in rng h by FUNCT_1:def 3;
    C in dom h by A1,A31,ENUMSET1:def 1;
    then
A38: h.C in rng h by FUNCT_1:def 3;
A39: xx c= h.B /\ h.C /\ h.D
    proof
      let m be object;
      assume m in xx;
      then
A40:  m in meet (rng h) by A32,A34,A37,SETFAM_1:def 9;
      then m in h.B & m in h.C by A37,A38,SETFAM_1:def 1;
      then
A41:  m in h.B /\ h.C by XBOOLE_0:def 4;
      m in h.D by A36,A40,SETFAM_1:def 1;
      hence thesis by A41,XBOOLE_0:def 4;
    end;
    then m<>{} by A35;
    then
A42: not m in {{}} by TARSKI:def 1;
    D in G by A1,ENUMSET1:def 1;
    then
A43: h.D in D by A33;
A44: not x in {{}} by A35,TARSKI:def 1;
    C in G by A1,ENUMSET1:def 1;
    then
A45: h.C in C by A33;
    B in G by A1,ENUMSET1:def 1;
    then h.B in B by A33;
    then m in INTERSECTION(B,C) by A45,SETFAM_1:def 5;
    then m in INTERSECTION(B,C) \ {{}} by A42,XBOOLE_0:def 5;
    then
A46: m in B '/\' C by PARTIT1:def 4;
    h.B /\ h.C /\ h.D c= xx
    proof
      let m be object;
      assume
A47:  m in h.B /\ h.C /\ h.D;
      then
A48:  m in h.B /\ h.C by XBOOLE_0:def 4;
A49:  rng h c= {h.B,h.C,h.D}
      proof
        let u be object;
        assume u in rng h;
        then consider x1 being object such that
A50:    x1 in dom h and
A51:    u = h.x1 by FUNCT_1:def 3;
        now
          per cases by A1,A31,A50,ENUMSET1:def 1;
          case
            x1=B;
            hence thesis by A51,ENUMSET1:def 1;
          end;
          case
            x1=C;
            hence thesis by A51,ENUMSET1:def 1;
          end;
          case
            x1=D;
            hence thesis by A51,ENUMSET1:def 1;
          end;
        end;
        hence thesis;
      end;
      for y being set holds y in rng h implies m in y
      proof
        let y be set;
        assume
A52:    y in rng h;
        now
          per cases by A49,A52,ENUMSET1:def 1;
          case
            y=h.B;
            hence thesis by A48,XBOOLE_0:def 4;
          end;
          case
            y=h.C;
            hence thesis by A48,XBOOLE_0:def 4;
          end;
          case
            y=h.D;
            hence thesis by A47,XBOOLE_0:def 4;
          end;
        end;
        hence thesis;
      end;
      then m in meet (rng h) by A37,SETFAM_1:def 1;
      hence thesis by A32,A34,A37,SETFAM_1:def 9;
    end;
    then (h.B /\ h.C) /\ h.D = x by A39,XBOOLE_0:def 10;
    then x in INTERSECTION(B '/\' C,D) by A43,A46,SETFAM_1:def 5;
    then x in INTERSECTION(B '/\' C,D) \ {{}} by A44,XBOOLE_0:def 5;
    hence thesis by PARTIT1:def 4;
  end;
  hence thesis by A5,XBOOLE_0:def 10;
end;
