reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem Th3:
  Component_of {}GX = the carrier of GX
proof
  defpred P[set] means ex A1 being Subset of GX st A1 = $1 & A1 is connected &
  {}GX c= $1;
  consider F being Subset-Family of GX such that
A1: for A being Subset of GX holds A in F iff P[A] from SUBSET_1:sch 3;
A2: for A being Subset of GX holds A in F iff A is connected & {}GX c= A
  proof
    let A be Subset of GX;
    thus A in F implies A is connected & {}GX c= A
    proof
      assume A in F;
      then
      ex A1 being Subset of GX st A1 = A & A1 is connected & {}GX c= A by A1;
      hence thesis;
    end;
    thus thesis by A1;
  end;
  now
    let x be object;
    hereby
      assume x in the carrier of GX;
      then reconsider p = x as Point of GX;
      reconsider Y = Component_of p as set;
      take Y;
      thus x in Y by CONNSP_1:38;
      Component_of p is connected & {}GX c= Y;
      hence Y in F by A2;
    end;
    given Y being set such that
A3: x in Y & Y in F;
    thus x in the carrier of GX by A3;
  end;
  then union F = the carrier of GX by TARSKI:def 4;
  hence thesis by A2,Def1;
end;
