
theorem lemNor1deg:
for F being Field
for G being non empty FinSequence of the carrier of Polynom-Ring F
st for i being Element of dom G holds G.i <> 0_.(F)
for q being Polynomial of F st q = Product G
for i being Element of dom G,
    p being Polynomial of F st p = G.i holds deg p <= deg q
proof
let F be Field;
let G be non empty FinSequence of the carrier of Polynom-Ring F;
assume AS: for i being Element of dom G holds G.i <> 0_.(F);
let q be Polynomial of F;
assume A: q = Product G;
let i be Element of dom G, p be Polynomial of F;
assume B: p = G.i;
dom G = Seg(len G) by FINSEQ_1:def 3; then
1 <= i & i <= len G by FINSEQ_1:1; then
G = (G|(i-'1)) ^ <*G.i*> ^ (G/^i) by FINSEQ_5:84; then
D: Product G
 = Product(G|(i-'1)^<*G.i*>) * Product((G/^i)) by GROUP_4:5
.= (Product(G|(i-'1)) * Product(<*G.i*>)) * Product(G/^i) by GROUP_4:5
.= (Product(<*G.i*>) * Product(G|(i-'1))) * Product(G/^i) by GROUP_1:def 12
.= Product(<*G.i*>) *(Product(G|(i-'1)) * Product(G/^i)) by GROUP_1:def 3;
reconsider r1 = Product(G|(i-'1)),
           r2 = Product(G/^i) as Polynomial of F by POLYNOM3:def 10;
I: G.i = G/.i by PARTFUN1:def 6; then
E: Product(<*G/.i*>) = p by B,GROUP_4:9;
Z: r1 *' r2 = Product(G|(i-'1)) * Product(G/^i) by POLYNOM3:def 10; then
F: q = p *' (r1 *' r2) by A,D,E,I,POLYNOM3:def 10;
G1: r1 *' r2 = Product(G|(i-'1) ^ (G/^i)) by Z,GROUP_4:5;
per cases;
suppose G|(i-'1) ^ (G/^i) = {};
  then G|(i-'1) ^ (G/^i) = <*>(the carrier of Polynom-Ring F);
  then Product(G|(i-'1) ^ (G/^i))
             = 1_(Polynom-Ring F) by GROUP_4:8
            .= 1_.F by POLYNOM3:def 10;
  hence thesis by F,G1;
  end;
suppose S: G|(i-'1) ^ (G/^i) <> {};
G: r1 *' r2 <> 0_.F
   proof
   now let j be Element of dom(G|(i-'1) ^ (G/^i));
     per cases by S,FINSEQ_1:25;
     suppose T: j in dom(G|(i-'1));
       G3: G|(i-'1) = G|Seg(i-'1) by FINSEQ_1:def 16;
       G2: dom(G|(i-'1)) c= dom G by FINSEQ_5:18;
       (G|(i-'1) ^ (G/^i)).j = (G|(i-'1)).j by T,FINSEQ_1:def 7
                            .= G.j by T,G3,FUNCT_1:47;
       hence (G|(i-'1) ^ (G/^i)).j <> 0_.(F) by T,G2,AS;
       end;
     suppose ex n being Nat st n in dom(G/^i) & j = len (G|(i-'1)) + n;
       then consider n being Nat such that
       G2: n in dom(G/^i) & j = len (G|(i-'1)) + n;
       G3: i + n in dom G by G2,FINSEQ_5:26;
       (G|(i-'1) ^ (G/^i)).j = (G/^i).n by G2,FINSEQ_1:def 7
                            .= G.(i+n) by G2,FINSEQ_5:27;
       hence (G|(i-'1) ^ (G/^i)).j <> 0_.(F) by G3,AS;
       end;
     end;
   hence thesis by S,G1,lemNor1dega;
   end; then
H: deg(r1*'r2) is Nat by T8;
p <> 0_.F by B,AS; then
deg q = deg p + deg(r1*'r2) by F,G,HURWITZ:23;
hence deg p <= deg q by H,INT_1:6;
end;
end;
