
theorem Th3:
  for T being non empty 1-sorted, S being sequence of T, A being
Subset of T holds (for S1 being subsequence of S holds not rng S1 c= A) implies
ex n being Element of NAT st for m being Element of NAT st n <= m holds not S.m
  in A
proof
  let T be non empty 1-sorted, S be sequence of T, A be Subset of T;
  assume
A1: for S1 being subsequence of S holds not rng S1 c= A;
  defpred Q[set] means $1 in A;
  assume
  for n being Element of NAT ex m being Element of NAT st n <= m & S.m in A;
  then
A2: for n being Element of NAT ex m being Element of NAT st n <= m & Q[S.m];
  consider S1 being subsequence of S such that
A3: for n being Element of NAT holds Q[S1.n] from VALUED_1:sch 1(A2);
  rng S1 c= A
  proof
    let y be object;
    assume y in rng S1;
    then consider x1 being object such that
A4: x1 in dom S1 and
A5: S1.x1 = y by FUNCT_1:def 3;
    reconsider n=x1 as Element of NAT by A4;
    S1.n in A by A3;
    hence thesis by A5;
  end;
  hence contradiction by A1;
end;
