reserve G,G1,G2 for _Graph;
reserve e,x,y for set;
reserve v,v1,v2 for Vertex of G;
reserve W for Walk of G;

theorem Th2:
  for G1 being non _trivial _Graph, v being Vertex of G1, G2 being
removeVertex of G1,v st G2 is connected & ex e being set st e in v.edgesInOut()
  & not e Joins v,v,G1 holds G1 is connected
proof
  let G1 be non _trivial _Graph, v be Vertex of G1,
      G2 be removeVertex of G1,v;
  assume that
A1: G2 is connected and
A2: ex e being set st e in v.edgesInOut() & not e Joins v,v,G1;
A3: now
    let x be Vertex of G1;
    assume x <> v;
    then not x in {v} by TARSKI:def 1;
    then x in (the_Vertices_of G1) \ {v} by XBOOLE_0:def 5;
    hence x in (the_Vertices_of G2) by GLIB_000:47;
  end;
  consider e being set such that
A4: e in v.edgesInOut() and
A5: not e Joins v,v,G1 by A2;
  set v3 = v.adj(e);
  v <> v3 by A4,A5,GLIB_000:67;
  then reconsider v39=v3 as Vertex of G2 by A3;
A6: e Joins v,v3,G1 by A4,GLIB_000:67;
  then
A7: e Joins v3,v,G1 by GLIB_000:14;
  now
    let v1, v2 be Vertex of G1;
    now
      per cases;
      suppose
        v1 <> v;
        then reconsider v19=v1 as Vertex of G2 by A3;
        now
          per cases;
          suppose
            v2 <> v;
            then reconsider v29=v2 as Vertex of G2 by A3;
            consider W9 being Walk of G2 such that
A8:         W9 is_Walk_from v19,v29 by A1;
            reconsider W=W9 as Walk of G1 by GLIB_001:167;
            W is_Walk_from v1,v2 by A8,GLIB_001:19;
            hence ex W being Walk of G1 st W is_Walk_from v1,v2;
          end;
          suppose
A9:         v2 = v;
            consider W9 being Walk of G2 such that
A10:        W9 is_Walk_from v19,v39 by A1;
            reconsider W=W9 as Walk of G1 by GLIB_001:167;
            W is_Walk_from v1,v3 by A10,GLIB_001:19;
            then W.first() = v1 & W.last() = v3 by GLIB_001:def 23;
            then W.addEdge(e) is_Walk_from v1, v2 by A7,A9,GLIB_001:63;
            hence ex W being Walk of G1 st W is_Walk_from v1,v2;
          end;
        end;
        hence ex W being Walk of G1 st W is_Walk_from v1,v2;
      end;
      suppose
A11:    v1 = v;
        now
          per cases;
          suppose
            v2 <> v;
            then reconsider v29=v2 as Vertex of G2 by A3;
            set W1 = G1.walkOf(v1,e,v3);
            consider W29 being Walk of G2 such that
A12:        W29 is_Walk_from v39,v29 by A1;
            reconsider W2=W29 as Walk of G1 by GLIB_001:167;
A13:        W2 is_Walk_from v3, v2 by A12,GLIB_001:19;
            take W = W1.append(W2);
            W1 is_Walk_from v1, v3 by A6,A11,GLIB_001:15;
            hence W is_Walk_from v1,v2 by A13,GLIB_001:31;
          end;
          suppose
A14:        v2 = v;
            take W = G1.walkOf(v);
            thus W is_Walk_from v1,v2 by A11,A14,GLIB_001:13;
          end;
        end;
        hence ex W being Walk of G1 st W is_Walk_from v1,v2;
      end;
    end;
    hence ex W being Walk of G1 st W is_Walk_from v1,v2;
  end;
  hence thesis;
end;
