reserve p,p1,p2,q for Point of TOP-REAL 2,
  f,f1,f2,g,g1,g2 for FinSequence of TOP-REAL 2,
  r,s for Real,

  n,m,i,j,k for Nat,
  G for Go-board,
  x for set;

theorem Th3:
  k<>0 & len f = k+1 implies L~f = L~(f|k) \/ LSeg(f,k)
proof
  assume that
A1: k<>0 and
A2: len f = k+1;
A3: 0+1<=k by A1,NAT_1:13;
  set f1 = f|k, lf = {LSeg(f,i): 1<=i & i+1 <= len f}, l1 = {LSeg(f1,j): 1<=j
  & j+1 <= len f1};
  k<=len f by A2,NAT_1:13;
  then
A4: len(f|k)=k by FINSEQ_1:59;
  thus L~f c= L~(f|k) \/ LSeg(f,k)
  proof
    let x be object;
    assume x in L~f;
    then consider X be set such that
A5: x in X and
A6: X in lf by TARSKI:def 4;
    consider n such that
A7: X=LSeg(f,n) and
A8: 1<=n and
A9: n+1 <= len f by A6;
    now
      per cases;
      suppose
        n+1 = len f;
        hence thesis by A2,A5,A7,XBOOLE_0:def 3;
      end;
      suppose
A10:    n+1 <> len f;
A11:    1<=n+1 by A8,NAT_1:13;
        n<=k by A2,A9,XREAL_1:6;
        then
A12:    n in dom f1 by A4,A8,FINSEQ_3:25;
A13:    n+1 < len f by A9,A10,XXREAL_0:1;
        then n+1 <= k by A2,NAT_1:13;
        then n+1 in dom f1 by A4,A11,FINSEQ_3:25;
        then
A14:    X=LSeg(f1,n) by A7,A12,TOPREAL3:17;
        n+1<=k by A2,A13,NAT_1:13;
        then X in l1 by A4,A8,A14;
        then x in union l1 by A5,TARSKI:def 4;
        hence thesis by XBOOLE_0:def 3;
      end;
    end;
    hence thesis;
  end;
A15: k<=k+1 by NAT_1:11;
  let x be object such that
A16: x in L~f1 \/ LSeg(f,k);
  now
    per cases by A16,XBOOLE_0:def 3;
    suppose
      x in L~f1;
      then consider X be set such that
A17:  x in X and
A18:  X in l1 by TARSKI:def 4;
      consider n such that
A19:  X=LSeg(f1,n) and
A20:  1<=n and
A21:  n+1 <= len f1 by A18;
      n<=n+1 by NAT_1:11;
      then n<=len f1 by A21,XXREAL_0:2;
      then
A22:  n in dom f1 by A20,FINSEQ_3:25;
      1<=n+1 by NAT_1:11;
      then n+1 in dom f1 by A21,FINSEQ_3:25;
      then
A23:  X=LSeg(f,n) by A19,A22,TOPREAL3:17;
      n+1<=len f by A2,A15,A4,A21,XXREAL_0:2;
      then X in lf by A20,A23;
      hence thesis by A17,TARSKI:def 4;
    end;
    suppose
A24:  x in LSeg(f,k);
      LSeg(f,k) in lf by A2,A3;
      hence thesis by A24,TARSKI:def 4;
    end;
  end;
  hence thesis;
end;
