reserve f for non constant standard special_circular_sequence,
  i,j,k,i1,i2,j1,j2 for Nat,
  r,s,r1,s1,r2,s2 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board;

theorem Th3:
  for GX being non empty TopSpace, A, B being non empty Subset of GX
  st A c= B & A is connected
  ex C being Subset of GX st C is_a_component_of B & A c= C
proof
  let GX be non empty TopSpace, A, B be non empty Subset of GX such that
A1: A c= B and
A2: A is connected;
  consider p being object such that
A3: p in A by XBOOLE_0:def 1;
A4: B = [#](GX|B) by PRE_TOPC:def 5
    .= the carrier of GX|B;
  then reconsider p as Point of GX|B by A1,A3;
  reconsider C = Component_of p as Subset of GX by PRE_TOPC:11;
  take C;
A5: Component_of p is a_component by CONNSP_1:40;
  hence C is_a_component_of B by CONNSP_1:def 6;
  reconsider AA = A as Subset of GX|B by A1,A4;
  GX|A is connected by A2,CONNSP_1:def 3;
  then GX|B|AA is connected by Th2;
  then
A6: AA is connected by CONNSP_1:def 3;
  p in Component_of p by CONNSP_1:38;
  then AA /\ Component_of p <> {}(GX|B) by A3,XBOOLE_0:def 4;
  then AA meets Component_of p;
  hence thesis by A5,A6,CONNSP_1:36;
end;
