reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem Th3:
  1 <= i & i < len G & 1 <= j & j < width G implies cell(G,i,j) =
  product ((1,2) --> ([.G*(i,1)`1,G*(i+1,1)`1.],[.G*(1,j)`2,G*(1,j+1)`2.]))
proof
A1: [.G*(1,j)`2,G*(1,j+1)`2.] =
  {b where b is Real : G*(1,j)`2 <= b & b <= G
  *(1,j+1)`2 } by RCOMP_1:def 1;
  set f = (1,2) --> ([.G*(i,1)`1,G*(i+1,1)`1.],[.G*(1,j)`2,G*(1,j+1)`2.]);
A2: dom f = {1,2} by FUNCT_4:62;
  assume 1 <= i & i < len G & 1 <= j & j < width G;
  then
A3: cell(G,i,j) = { |[r,s]| where r, s is Real:
   G*(i,1)`1 <= r & r <= G*(i+1
  ,1)`1 & G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } by GOBRD11:32;
A4: [.G*(i,1)`1,G*(i+1,1)`1.] = {a where a is Real :
   G*(i,1)`1 <= a & a <= G
  *(i+1,1)`1 } by RCOMP_1:def 1;
  thus cell(G,i,j) c= product f
  proof
    let c be object;
    assume c in cell(G,i,j);
    then consider r, s being Real such that
A5: c = |[r,s]| and
A6: G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & G*(1,j)`2 <= s & s <= G*(1,j+1
    )`2 by A3;
A7: r in [.G*(i,1)`1,G*(i+1,1)`1.] & s in [.G*(1,j)`2,G*(1,j+1)`2.] by A4,A1,A6
;
A8: for x being object st x in dom f holds <*r,s*>.x in f.x
    proof
      let x be object;
      assume x in dom f;
      then
A10:  x = 1 or x = 2 by TARSKI:def 2;
      thus thesis by A7,A10,FUNCT_4:63;
    end;
    dom <*r,s*> = {1,2} by FINSEQ_1:2,89;
    hence thesis by A2,A5,A8,CARD_3:9;
  end;
  let c be object;
  assume c in product f;
  then consider g being Function such that
A11: c = g and
A12: dom g = dom f and
A13: for x being object st x in dom f holds g.x in f.x by CARD_3:def 5;
  2 in dom f by A2,TARSKI:def 2;
  then g.2 in f.2 by A13;
  then g.2 in [.G*(1,j)`2,G*(1,j+1)`2.] by FUNCT_4:63;
  then consider b being Real such that
A14: g.2 = b and
A15: G*(1,j)`2 <= b & b <= G*(1,j+1)`2 by A1;
  1 in dom f by A2,TARSKI:def 2;
  then g.1 in f.1 by A13;
  then g.1 in [.G*(i,1)`1,G*(i+1,1)`1.] by FUNCT_4:63;
  then consider a being Real such that
A16: g.1 = a and
A17: G*(i,1)`1 <= a & a <= G*(i+1,1)`1 by A4;
A18: for k being object st k in dom g holds g.k = <*a,b*>.k
  proof
    let k be object;
    assume k in dom g;
    then k = 1 or k = 2 by A12,TARSKI:def 2;
    hence thesis by A16,A14;
  end;
  dom <*a,b*> = {1,2} by FINSEQ_1:2,89;
  then c = |[a,b]| by A11,A12,A18,FUNCT_1:2,FUNCT_4:62;
  hence thesis by A3,A17,A15;
end;
