
theorem Th3:
for seq be Real_Sequence st seq is divergent_to-infty
 holds not seq is divergent_to+infty & not seq is convergent
proof
    let seq be Real_Sequence;
    assume A1: seq is divergent_to-infty;
    hereby assume seq is divergent_to+infty; then
     consider n1 be Nat such that
A2:   for m be Nat st n1<=m holds 0 < seq.m by LIMFUNC1:def 4;
     consider n2 be Nat such that
A3:   for m be Nat st n2<=m holds seq.m < 0 by A1,LIMFUNC1:def 5;
     reconsider m = max(n1,n2) as Element of NAT by ORDINAL1:def 12;
     seq.m < 0 & seq.m > 0 by A2,A3,XXREAL_0:25;
     hence contradiction;
    end;
    assume seq is convergent; then
    consider g be Real such that
A4:  for p be Real st 0<p ex n be Nat st for m be Nat st n<=m holds
      |.seq.m-g.| < p by SEQ_2:def 6;

    per cases;
    suppose A5: g > 0; then
     consider n1 be Nat such that
A6:   for m be Nat st n1 <= m holds |.seq.m- g.| < g by A4;
A7:  now
      let m be Nat;
      assume n1 <= m; then
      |.seq.m- g.| <  g by A6; then
A8:   -g < -|.seq.m-g.| by XREAL_1:24;
      -|.seq.m-g.| <= seq.m-g by ABSVALUE:4; then
      -g < seq.m-g by A8,XXREAL_0:2; then
      -g+g < seq.m by XREAL_1:20;
      hence 0 < seq.m;
     end;
     consider n2 be Nat such that
A9:   for m be Nat st n2 <= m holds seq.m <  -g by A1,LIMFUNC1:def 5;
     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
     0 < seq.m by A7,XXREAL_0:25;
     hence contradiction by A5,A9,XXREAL_0:25;
    end;
    suppose g < 0; then
     consider n1 be Nat such that
A10:  for m be Nat st n1 <= m holds |.seq.m- g.| <  -g by A4,XREAL_1:58;
A11: now
      let m be Element of NAT;
      assume n1 <= m; then
      |.seq.m- g.| <  -g by A10; then
A12:   --g < -|.seq.m-g.| by XREAL_1:24;
      -|.seq.m-g.| <= seq.m-g by ABSVALUE:4; then
      --g < seq.m - g by A12,XXREAL_0:2; then
      g+g < seq.m by XREAL_1:20;
      hence (2*g) < seq.m;
     end;
     consider n2 be Nat such that
A13:  for m be Nat st n2 <= m holds seq.m < 2*g by A1,LIMFUNC1:def 5;

     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
     (2*g) < seq.m by A11,XXREAL_0:25;
     hence contradiction by A13,XXREAL_0:25;
    end;
    suppose A14: g = 0;
     consider n1 be Nat such that
A15:  for m be Nat st n1 <= m holds |. seq.m- g .| <  1 by A4;
     consider n2 be Nat such that
A16:  for m be Nat st n2 <= m holds  seq.m < -1 by A1,LIMFUNC1:def 5;
     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
A17: |. seq.m-0 .| <  1 by A14,A15,XXREAL_0:25;

A18: seq.m < -1 by A16,XXREAL_0:25;
     --1 < -seq.m by A18,XREAL_1:24;
     hence contradiction by A17,A18,ABSVALUE:def 1;
    end;
end;
