reserve a,b,r,x,y for Real,
  i,j,k,n for Nat,
  x1 for set;

theorem
  for p being real-valued FinSequence
  ex q be non-decreasing FinSequence of REAL st p,q are_fiberwise_equipotent
proof
  let p be real-valued FinSequence;
  consider q being non-increasing FinSequence of REAL such that
A1: p,q are_fiberwise_equipotent by RFINSEQ:22;
  for n be Nat st n in dom Rev q & n+1 in dom Rev q holds
  (Rev q).n <= (Rev q).(n+1)
  proof
    let n;
    assume that
A2: n in dom Rev q and
A3: n+1 in dom Rev q;
    (Rev q).n <= (Rev q).(n+1)
    proof
      n in Seg len Rev q by A2,FINSEQ_1:def 3;
      then 1 <= n by FINSEQ_1:1;
      then n - 1 >= 0 by XREAL_1:48;
      then len q + 0 <= len q + (n - 1) by XREAL_1:7;
      then
A4:   len q - (n - 1) <= len q by XREAL_1:20;
      n in Seg len Rev q by A2,FINSEQ_1:def 3;
      then n in Seg len q by FINSEQ_5:def 3;
      then n <= len q by FINSEQ_1:1;
      then consider m being Nat such that
A5:   len q = n + m by NAT_1:10;
      reconsider m as Nat;
      m + 1 = len q - n + 1 & 1 <= len q - n + 1 by A5,NAT_1:11;
      then len q - n + 1 in Seg len q by A4,FINSEQ_1:1;
      then
A6:   len q - n + 1 in dom q by FINSEQ_1:def 3;
      set x=(Rev q).n, y=(Rev q).(n+1);
A7:   len q - (n+1) + 1 = len q-n;
      len q <= len q + n by NAT_1:11;
      then
A8:   len q - (n+1) + 1 <= len q by A7,XREAL_1:20;
      n+1 in Seg len Rev q by A3,FINSEQ_1:def 3;
      then n+1 in Seg len q by FINSEQ_5:def 3;
      then n+1 <= len q by FINSEQ_1:1;
      then 1 <= len q - (n+1) + 1 by A7,XREAL_1:19;
      then len q - (n+1) + 1 in Seg len q by A5,A8,FINSEQ_1:1;
      then
A9:   len q - (n+1) + 1 in dom q by FINSEQ_1:def 3;
      x = q.(len q - n + 1) & y = q.(len q - (n+1) + 1)
      by A2,A3,FINSEQ_5:def 3;
      hence thesis by A6,A9,RFINSEQ:def 3;
    end;
    hence thesis;
  end;
  then reconsider r=Rev q as non-decreasing FinSequence of REAL by Def1;
  take r;
  p,Rev q are_fiberwise_equipotent
  proof
    defpred P[Nat] means
    for p be real-valued FinSequence,
        q be non-increasing real-valued FinSequence
    st len p = $1 & p,q are_fiberwise_equipotent
    holds p,Rev q are_fiberwise_equipotent;
A10: for k st P[k] holds P[k+1]
    proof
      let k;
      assume
A11:  P[k];
      P[k+1]
      proof
        let p be real-valued FinSequence;
        let q be non-increasing real-valued FinSequence;
        consider q1 being non-increasing FinSequence of REAL such that
A12:    p,q1 are_fiberwise_equipotent by RFINSEQ:22;
        reconsider kk= k as Element of NAT by ORDINAL1:def 12;
        reconsider q1k = q1|kk as non-increasing FinSequence of REAL
        by RFINSEQ:20;
A13:    Rev(q1k)^<*q1.(k+1)*>,<*q1.(k+1)*>^Rev(q1k)
        are_fiberwise_equipotent by RFINSEQ:2;
        assume
A14:    len p = k+1;
        then
A15:    len q1= k+1 by A12,RFINSEQ:3;
        len p = len q1 by A12,RFINSEQ:3;
        then len(q1|k) = k by A14,FINSEQ_1:59,NAT_1:11;
        then q1|k,Rev(q1k) are_fiberwise_equipotent by A11;
        then (q1|k)^<*q1.(k+1)*>,Rev(q1k)^<*q1.(k+1)*>
        are_fiberwise_equipotent by RFINSEQ:1;
        then q1,Rev(q1k)^<*q1.(k+1)*> are_fiberwise_equipotent by A15,RFINSEQ:7
;
        then
A16:    q1,<*q1.(k+1)*>^Rev(q1k) are_fiberwise_equipotent by A13,CLASSES1:76;
A17:    <*q1.(k+1)*>^Rev(q1k) = Rev((q1|k)^<*q1.(k+1)*>) by FINSEQ_5:63
          .= Rev(q1) by A15,RFINSEQ:7;
        assume p,q are_fiberwise_equipotent;
        then q=q1 by A12,CLASSES1:76,RFINSEQ:23;
        hence thesis by A12,A16,A17,CLASSES1:76;
      end;
      hence thesis;
    end;
A18: len p = len p;
A19: P[0]
    proof
      let p be real-valued FinSequence;
      let q be non-increasing real-valued FinSequence;
      assume
A20:  len p = 0;
      assume p,q are_fiberwise_equipotent;
      then len q = 0 by A20,RFINSEQ:3;
      then len Rev q = 0 by FINSEQ_5:def 3;
      then Rev q = {};
      then
A21:  rng Rev q = {};
      p = {} by A20;
      then
A22:  rng p = {};
      for x be object holds card Coim(p,x) = card Coim(Rev q,x)
      proof
        let x be object;
        card (p"{x}) = 0 by A22,CARD_1:27,FUNCT_1:72;
        hence thesis by A21,CARD_1:27,FUNCT_1:72;
      end;
      hence thesis by CLASSES1:def 10;
    end;
    for k holds P[k] from NAT_1:sch 2(A19,A10);
    hence thesis by A1,A18;
  end;
  hence thesis;
end;
