reserve A,B,C,D for Category,
  F for Functor of A,B,
  G for Functor of B,C;

theorem Th1:
 for a,b being Object of A
  for f being Morphism of a,b st f is invertible holds F/.f is invertible
proof let a,b be Object of A;
  let f be Morphism of a,b  such that
A1: Hom(a,b) <> {} & Hom(b,a) <> {};
  given g being Morphism of b,a such that
A2: f*g = id b and
A3: g*f = id a;
A4: dom g = b by A1,CAT_1:5 .= cod f by A1,CAT_1:5;
A5: cod g = a by A1,CAT_1:5 .= dom f by A1,CAT_1:5;
A6: cod f = b by A1,CAT_1:5;
A7: dom f = a by A1,CAT_1:5;
A8: f(*)g = id cod f by A2,A1,A6,CAT_1:def 13;
A9: g(*)f = id dom f by A3,A1,A7,CAT_1:def 13;
  thus
A10: Hom(F.a,F.b) <> {} & Hom(F.b,F.a) <> {} by A1,CAT_1:84;
  take F/.g;
A11: F/.f = F.f by A1,CAT_3:def 10;
A12: F/.g = F.g by A1,CAT_3:def 10;
  thus (F/.f)*(F/.g) = (F.f)(*)(F.g) by A10,A11,A12,CAT_1:def 13
    .= F.(f(*)g) by A5,CAT_1:64
    .= id cod(F/.f) by A8,A11,CAT_1:63
    .= id(F.b) by A10,CAT_1:5;
  thus (F/.g)*(F/.f) = (F.g)(*)(F.f) by A10,A11,A12,CAT_1:def 13
    .= F.(g(*)f) by A4,CAT_1:64
    .= id dom(F/.f) by A9,A11,CAT_1:63
    .= id(F.a) by A10,CAT_1:5;
end;
