reserve a, b, i, k, m, n for Nat,
  r for Real,
  D for non empty Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2;

theorem Th3:
  2 <= m & m < len Gauge(D,i) & 1 <= a & a <= len Gauge(D,i) & 1 <=
b & b <= len Gauge(D,i+1) implies Gauge(D,i)*(m,a)`1 = Gauge(D,i+1)*(2*m-'2,b)
  `1
proof
  set I = Gauge(D,i), J = Gauge(D,i+1), z = N-bound D, e = E-bound D, s =
  S-bound D, w = W-bound D;
  assume that
A1: 2 <= m and
A2: m < len I and
A3: 1 <= a and
A4: a <= len I and
A5: 1 <= b and
A6: b <= len J;
  m < 2|^i + 3 by A2,JORDAN8:def 1;
  then 2*m-'2 <= 2|^(i+1) + 3 by Lm13;
  then
A7: 2*m-'2 <= len J by JORDAN8:def 1;
A8: len J = width J by JORDAN8:def 1;
  1 <= 2*m-'2 by A1,Lm11;
  then
A9: [2*m-'2,b] in Indices J by A5,A6,A8,A7,MATRIX_0:30;
A10: len I = width I by JORDAN8:def 1;
  1 <= m by A1,XXREAL_0:2;
  then [m,a] in Indices I by A2,A3,A4,A10,MATRIX_0:30;
  hence I*(m,a)`1 = |[w+((e-w)/(2|^i))*(m-2),s+((z-s)/(2|^i))*(a-2)]|`1 by
JORDAN8:def 1
    .= w+((e-w)/(2|^i))*(m-2) by EUCLID:52
    .= w+((e-w)/(2|^(i+1)))*(2*m-'2-2) by A1,Lm10
    .= |[w+((e-w)/(2|^(i+1)))*(2*m-'2-2),s+((z-s)/(2|^(i+1)))*(b-2)]|`1 by
EUCLID:52
    .= J*(2*m-'2,b)`1 by A9,JORDAN8:def 1;
end;
