reserve p1, p2 for Point of TOP-REAL 2,
  C for Simple_closed_curve,
  P for Subset of TOP-REAL 2;

theorem Th3:
  for A,B,D being Real st p1,p2 realize-max-dist-in P holds
AffineMap(A,B,A,D).p1,AffineMap(A,B,A,D).p2 realize-max-dist-in AffineMap(A,B,A
  ,D).:P
proof
  let A,B,D be Real;
  set a=p1,b=p2,C=P;
A1: dom AffineMap(A,B,A,D) = the carrier of TOP-REAL 2 by FUNCT_2:def 1;
  assume
A2: a,b realize-max-dist-in C;
  then a in C;
  hence AffineMap(A,B,A,D).a in AffineMap(A,B,A,D).:C by A1,FUNCT_1:def 6;
  b in C by A2;
  hence AffineMap(A,B,A,D).b in AffineMap(A,B,A,D).:C by A1,FUNCT_1:def 6;
  let x, y be Point of TOP-REAL 2;
  assume x in AffineMap(A,B,A,D).:C;
  then consider X being object such that
A3: X in dom AffineMap(A,B,A,D) and
A4: X in C and
A5: AffineMap(A,B,A,D).X=x by FUNCT_1:def 6;
  reconsider X as Point of TOP-REAL 2 by A3;
  assume y in AffineMap(A,B,A,D).:C;
  then consider Y being object such that
A6: Y in dom AffineMap(A,B,A,D) and
A7: Y in C and
A8: AffineMap(A,B,A,D).Y=y by FUNCT_1:def 6;
  reconsider Y as Point of TOP-REAL 2 by A6;
A9: (X`1-Y`1)^2>=0 & (X`2-Y`2)^2>=0 by XREAL_1:63;
A10: (a`1-b`1)^2 >=0 & (a`2-b`2)^2 >=0 by XREAL_1:63;
A11: A^2>=0 by XREAL_1:63;
  then
A12: sqrt(A^2)>=0 by SQUARE_1:def 2;
A13: dist(AffineMap(A,B,A,D).a,AffineMap(A,B,A,D).b) = dist(|[A*(a`1)+B,A*(a
  `2)+D]|,AffineMap(A,B,A,D).b) by JGRAPH_2:def 2
    .= dist(|[A*(a`1)+B,A*(a`2)+D]|,|[A*(b`1)+B,A*(b`2)+D]|) by JGRAPH_2:def 2
    .= sqrt((|[A*(a`1)+B,A*(a`2)+D]|`1-|[A*(b`1)+B,A*(b`2)+D]|`1)^2 + (|[A*(
  a`1)+B,A*(a`2)+D]|`2-|[A*(b`1)+B,A*(b`2)+D]|`2)^2) by TOPREAL6:92
    .= sqrt((A*(a`1)+B-|[A*(b`1)+B,A*(b`2)+D]|`1)^2 + (|[A*(a`1)+B,A*(a`2)+D
  ]|`2-|[A*(b`1)+B,A*(b`2)+D]|`2)^2) by EUCLID:52
    .= sqrt((A*(a`1)+B-(A*(b`1)+B))^2 + (|[A*(a`1)+B,A*(a`2)+D]|`2-|[A*(b`1)
  +B,A*(b`2)+D]|`2)^2) by EUCLID:52
    .= sqrt((A*(a`1)+B-(A*(b`1)+B))^2 + (A*(a`2)+D-|[A*(b`1)+B,A*(b`2)+D]|`2
  )^2) by EUCLID:52
    .= sqrt((A*(a`1)+B-(A*(b`1)+B))^2 + (A*(a`2)+D-(A*(b`2)+D))^2) by EUCLID:52
    .= sqrt(A^2*((a`1-b`1)^2 + (a`2-b`2)^2))
    .= sqrt(A^2)*sqrt((a`1-b`1)^2 + (a`2-b`2)^2) by A11,A10,SQUARE_1:29
    .= sqrt(A^2)*dist(a,b) by TOPREAL6:92;
A14: dist(x,y) = dist(|[A*(X`1)+B,A*(X`2)+D]|,AffineMap(A,B,A,D).Y) by A5,A8,
JGRAPH_2:def 2
    .= dist(|[A*(X`1)+B,A*(X`2)+D]|,|[A*(Y`1)+B,A*(Y`2)+D]|) by JGRAPH_2:def 2
    .= sqrt((|[A*(X`1)+B,A*(X`2)+D]|`1-|[A*(Y`1)+B,A*(Y`2)+D]|`1)^2 + (|[A*(
  X`1)+B,A*(X`2)+D]|`2-|[A*(Y`1)+B,A*(Y`2)+D]|`2)^2) by TOPREAL6:92
    .= sqrt((A*(X`1)+B-|[A*(Y`1)+B,A*(Y`2)+D]|`1)^2 + (|[A*(X`1)+B,A*(X`2)+D
  ]|`2-|[A*(Y`1)+B,A*(Y`2)+D]|`2)^2) by EUCLID:52
    .= sqrt((A*(X`1)+B-(A*(Y`1)+B))^2 + (|[A*(X`1)+B,A*(X`2)+D]|`2-|[A*(Y`1)
  +B,A*(Y`2)+D]|`2)^2) by EUCLID:52
    .= sqrt((A*(X`1)+B-(A*(Y`1)+B))^2 + (A*(X`2)+D-|[A*(Y`1)+B,A*(Y`2)+D]|`2
  )^2) by EUCLID:52
    .= sqrt((A*(X`1)+B-(A*(Y`1)+B))^2 + (A*(X`2)+D-(A*(Y`2)+D))^2) by EUCLID:52
    .= sqrt(A^2*((X`1-Y`1)^2 + (X`2-Y`2)^2))
    .= sqrt(A^2)*sqrt((X`1-Y`1)^2 + (X`2-Y`2)^2) by A11,A9,SQUARE_1:29
    .= sqrt(A^2)*dist(X,Y) by TOPREAL6:92;
  dist(a,b) >= dist(X,Y) by A2,A4,A7;
  hence thesis by A13,A14,A12,XREAL_1:64;
end;
