reserve Omega, I for non empty set;
reserve Sigma for SigmaField of Omega;
reserve P for Probability of Sigma;
reserve D, E, F for Subset-Family of Omega;
reserve  B, sB for non empty Subset of Sigma;
reserve b for Element of B;
reserve a for Element of Sigma;
reserve p, q, u, v for Event of Sigma;
reserve n, m for Element of NAT;
reserve S, S9, X, x, y, z, i, j for set;

theorem Th3:
  for X being Subset-Family of Omega st X={} holds sigma(X) = {{}, Omega}
proof
  let X be Subset-Family of Omega;
A1: for A1 being SetSequence of Omega st rng A1 c= {{},Omega} holds Union A1
  in {{},Omega}
  proof
    let A1 be SetSequence of Omega;
    assume
A2: rng A1 c= {{},Omega};
A3: for n being Nat
    holds ((Partial_Union A1).n = {} or (Partial_Union A1).n = Omega )
    proof
      defpred P[Nat] means (Partial_Union A1).$1 = {} or (Partial_Union A1).$1
      = Omega;
      let n be Nat;
A4:   for k be Nat st P[k] holds P[k+1]
      proof
        let k be Nat;
        assume
A5:     (Partial_Union A1).k = {} or (Partial_Union A1).k = Omega;
        reconsider k as Element of NAT by ORDINAL1:def 12;
A6:     A1.(k+1) in rng A1 by NAT_1:51;
        per cases by A5,PROB_3:def 2;
        suppose
          (Partial_Union A1).(k+1) = {} \/ A1.(k+1);
          hence thesis by A2,A6,TARSKI:def 2;
        end;
        suppose
A7:       (Partial_Union A1).(k+1) = Omega \/ A1.(k+1);
          A1.(k+1) = {} or A1.(k+1) = Omega by A2,A6,TARSKI:def 2;
          hence thesis by A7;
        end;
      end;
      (Partial_Union A1).0 = A1.0 & A1.0 in rng A1 by NAT_1:51,PROB_3:def 2;
      then
A8:   P[0] by A2,TARSKI:def 2;
      for k being Nat holds P[k] from NAT_1:sch 2(A8,A4);
      hence thesis;
    end;
    Union Partial_Union A1 = {} or Union Partial_Union A1 = Omega
    proof
      per cases;
      suppose
A9:     for n being Nat holds (Partial_Union A1).n = {};
        not ex x being object st x in Union Partial_Union A1
        proof
          given x being object such that
A10:         x in Union Partial_Union A1;
           reconsider x as set by TARSKI:1;
           ex n being Nat st x in (Partial_Union A1).n by PROB_1:12,A10;
          hence contradiction by A9;
        end;
        hence thesis by XBOOLE_0:def 1;
      end;
      suppose
        not for n being Nat holds (Partial_Union A1).n = {};
        then consider n being Nat such that
A11:    (Partial_Union A1).n <> {};
        (Partial_Union A1).n = Omega by A3,A11;
        then for x being object holds
x in Omega implies x in Union Partial_Union A1 by PROB_1:12;
        then Omega c= Union Partial_Union A1;
        hence thesis;
      end;
    end;
    then Union A1 = {} or Union A1 = Omega by PROB_3:15;
    hence thesis by TARSKI:def 2;
  end;
A12: for A being Subset of Omega st A in {{},Omega} holds A` in {{},Omega}
  proof
    let A be Subset of Omega;
    assume A in {{},Omega};
    then A={} or A=Omega by TARSKI:def 2;
    then A`=Omega or A`={} by XBOOLE_1:37;
    hence thesis by TARSKI:def 2;
  end;
  {} in sigma(X) & Omega in sigma(X) by PROB_1:4,5;
  then for x being object holds
x in {{},Omega} implies x in sigma(X) by TARSKI:def 2;
  then
A13: {{},Omega} c= sigma(X);
  assume X={};
  then
A14: X c= {{},Omega};
  for x being object holds x in {{},Omega} implies x in bool Omega
  proof let x be object;
    reconsider xx=x as set by TARSKI:1;
    assume x in {{},Omega};
    then x={} or x=Omega by TARSKI:def 2;
    then xx c= Omega;
    hence thesis;
  end;
  then {{},Omega} is SigmaField of Omega by A1,A12,PROB_4:4,TARSKI:def 3;
  then sigma(X) c= {{},Omega} by A14,PROB_1:def 9;
  hence thesis by A13;
end;
