reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th3:
  j in Seg width A implies width DelCol(A,j) = width A-'1
proof
  set DC=DelCol(A,j);
A1: len DC = len A by MATRIX_0:def 13;
  assume
A2: j in Seg width A;
  then Seg width A <> {};
  then width A <>0;
  then len A > 0 by MATRIX_0:def 3;
  then consider t being FinSequence such that
A3: t in rng DC and
A4: len t = width DC by A1,MATRIX_0:def 3;
  consider k9 be object such that
A5: k9 in dom DelCol(A,j) and
A6: DC.k9 = t by A3,FUNCT_1:def 3;
  k9 in Seg len DC by A5,FINSEQ_1:def 3;
  then consider k being Nat such that
A7: k9=k and
  1<=k and
  k<=len DC;
  k in dom A by A1,A5,A7,FINSEQ_3:29;
  then
A8: t=Del(Line(A,k),j) by A6,A7,MATRIX_0:def 13;
A9: len Line(A,k)=width A by MATRIX_0:def 7;
  then dom Line(A,k)=Seg (width A) by FINSEQ_1:def 3;
  hence thesis by A2,A4,A9,A8,Th1;
end;
