reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th3:
  [:{a,b,c,d},{e,f,g,h}:] = {[a,e],[a,f],[b,e],[b,f],[a,g],[a,h],[b
  ,g],[b,h]} \/ {[c,e],[c,f],[d,e],[d,f],[c,g],[c,h],[d,g],[d,h]}
proof
  set X1 = {a,b,c,d}, Y1 = {e,f,g,h}, X11 = {a,b}, X12 = {c,d}, Y11 = {e,f},
  Y12 = {g,h};
A1: [:X12,Y11:] = {[c,e],[c,f],[d,e],[d,f]} & [:X12,Y12:] = {[c,g],[c,h],[d,
  g],[ d,h]} by MCART_1:23;
  X1 = X11 \/ X12 & Y1 = Y11 \/ Y12 by ENUMSET1:5;
  then
A2: [:X1,Y1:] = [:X11,Y11:] \/ [:X11,Y12:] \/ [:X12,Y11:] \/ [:X12,Y12:] by
ZFMISC_1:98;
  [:X11,Y11:] = {[a,e],[a,f],[b,e],[b,f]} & [:X11,Y12:] = {[a,g],[a,h],[b,
  g],[ b,h]} by MCART_1:23;
  then
  [:X1,Y1:] = {[a,e],[a,f],[b,e],[b,f],[a,g],[a,h],[b,g],[b,h]} \/ {[c,e],
  [c,f],[d,e],[d,f]} \/ {[c,g],[c,h],[d,g],[d,h]} by A1,A2,ENUMSET1:25
    .= {[a,e],[a,f],[b,e],[b,f],[a,g],[a,h],[b,g],[b,h]} \/ ({[c,e],[c,f],[d
  ,e],[d,f]} \/ {[c,g],[c,h],[d,g],[d,h]}) by XBOOLE_1:4
    .= {[a,e],[a,f],[b,e],[b,f],[a,g],[a,h],[b,g],[b,h]} \/ {[c,e],[c,f],[d,
  e],[d,f],[c,g],[c,h],[d,g],[d,h]} by ENUMSET1:25;
  hence thesis;
end;
