
theorem Th3:
  for i being Integer, n being Nat
  st n = 4*i+3 ex p,q being Nat st p = 4*q+3 & p is prime & p divides n
  proof
    defpred P[Nat] means
    (ex k being Nat st $1=4*k+3) implies
    ex p,q being Nat st p=4*q+3 & p is prime & p divides $1;
    let k be Integer, n be Nat such that
    A1: n = 4*k+3;
    now
      assume k < 0;
      then
B2:   k+1 <= 0 by INT_1:7;
      4*k+3-3 >= 0-3 by A1,XREAL_1:9;
      then 4*k/4 >= (-3)/4 by XREAL_1:72;
      then k+1 >= -3/4+1 by XREAL_1:7;
      hence contradiction by B2,XXREAL_0:2;
    end;
    then reconsider k as Element of NAT by INT_1:3;
B1: n=4*k+3 by A1;
    A2: for m being Nat st for l being Nat st l < m holds P[l] holds P[m]
    proof
      let m be Nat;
      assume A3: for l being Nat st l < m holds P[l];
      given k being Nat such that
      A4: m=4*k+3;
      m <> 0 & m <> 1 by A4,NAT_1:11;
      then m is non trivial by NAT_2:28;
      then consider l being prime Nat such that
      A5: l divides m by NEWTON03:29;
      reconsider l as Element of NAT by ORDINAL1:def 12;
      consider t being Nat such that
      A6: m = l*t by A5,NAT_D:def 3;
      A7: t divides m by A6;
      consider u being Element of NAT such that
      A8: l=4*u or l=4*u+1 or l=4*u+2 or l=4*u+3 by SCHEME1:3;
      per cases by A8;
      suppose l=4*u;
        then 4 divides l;
        then 4 divides m by A5,NAT_D:4;
        hence ex p,q being Nat st
        p=4*q+3 & p is prime & p divides m by A4,NUMBER02:32;
      end;
      suppose A9: l=4*u+1;
        reconsider t as Element of NAT by ORDINAL1:def 12;
        consider v being Element of NAT such that
        A10: t=4*v or t=4*v+1 or t=4*v+2 or t=4*v+3 by SCHEME1:3;
        per cases by A10;
        suppose t=4*v;
          then 4 divides t;
          then 4 divides m by A7,NAT_D:4;
          hence ex p,q being Nat st
          p=4*q+3 & p is prime & p divides m by A4,NUMBER02:32;
        end;
        suppose t=4*v+1;
          then m=4*(4*u*v+u+v)+1 by A6,A9;
          then A11: m mod 4 = 1 mod 4 by NAT_D:21
          .= 1 by NAT_D:24;
          m mod 4 = 3 mod 4 by A4,NAT_D:21
          .= 3 by NAT_D:24;
          hence ex p,q being Nat st
          p=4*q+3 & p is prime & p divides m by A11;
        end;
        suppose t=4*v+2;
          then t=2*(2*v+1);
          then A12: 2 divides t;
          m=2*(2*k+1)+1 by A4;
          hence ex p,q being Nat st
          p=4*q+3 & p is prime & p divides m by A12,A7;
        end;
        suppose A13: t=4*v+3;
          A14: t <= m by A6,NAT_D:def 3,INT_2:27;
          now
            assume t=m;
            then l=1 by A6,A4,XCMPLX_1:7;
            hence contradiction by INT_2:def 4;
          end; then
          t < m by A14,XXREAL_0:1;
          then consider p,q being Nat such that
          A15: p=4*q+3 & p is prime & p divides t by A13,A3;
          take p,q;
          thus p=4*q+3 & p is prime & p divides m by A15,A7,NAT_D:4;
        end;
      end;
      suppose l=4*u+2;
        then l=2*(2*u+1);
        then A16: 2 divides l;
        m=2*(2*k+1)+1 by A4;
        hence ex p,q being Nat st
        p=4*q+3 & p is prime & p divides m by A16,A5;
      end;
      suppose l=4*u+3;
        hence ex p,q being Nat st
        p=4*q+3 & p is prime & p divides m by A5;
      end;
    end;
    for n being Nat holds P[n] from NAT_1:sch 4(A2);
    then consider p,q being Nat such that
    A17: p=4*q+3 & p is prime & p divides n by B1;
    take p,q;
    thus thesis by A17;
  end;
