reserve i for Nat;
reserve R for Relation;
reserve A for set;
reserve PT for non empty TopSpace;
reserve PM for MetrSpace;
reserve FX,GX,HX for Subset-Family of PT;
reserve Y,V,W for Subset of PT;

theorem
  for PT,FX st PT is T_2 & PT is paracompact & FX is Cover of PT & FX is
open ex GX st GX is open & GX is Cover of PT & clf GX is_finer_than FX & GX is
  locally_finite
proof
  let PT,FX;
  assume that
A1: PT is T_2 and
A2: PT is paracompact and
A3: FX is Cover of PT & FX is open;
  consider HX such that
A4: HX is open & HX is Cover of PT and
A5: for V st V in HX ex W st W in FX & Cl V c= W by A1,A2,A3,Th2,PCOMPS_1:24;
  consider GX such that
A6: GX is open & GX is Cover of PT and
A7: GX is_finer_than HX and
A8: GX is locally_finite by A2,A4,PCOMPS_1:def 3;
A9: for V st V in GX ex W st W in FX & (Cl V) c= W
  proof
    let V;
    assume V in GX;
    then consider X being set such that
A10: X in HX and
A11: V c= X by A7;
    reconsider X as Subset of PT by A10;
    consider W such that
A12: W in FX & Cl X c= W by A5,A10;
    take W;
    Cl V c= Cl X by A11,PRE_TOPC:19;
    hence thesis by A12;
  end;
  clf GX is_finer_than FX
  proof
    let X be set;
    assume
A13: X in clf GX;
    then reconsider X as Subset of PT;
    consider V such that
A14: X = Cl V and
A15: V in GX by A13,PCOMPS_1:def 2;
    consider W such that
A16: W in FX & (Cl V) c= W by A9,A15;
    take W;
    thus thesis by A14,A16;
  end;
  hence thesis by A6,A8;
end;
