reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;

theorem Th3:
  for f be Function of Omega1,Omega2,
  B be SetSequence of Omega2,
  D be SetSequence of Omega1
  st for n be Element of NAT holds D.n = f "(B.n) holds
  f"(Intersection B) = Intersection D
  proof
    let f be Function of Omega1,Omega2,
    B be SetSequence of Omega2,
    D be SetSequence of Omega1;
    assume A1:for n be Element of NAT holds D.n = f "(B.n);
    set Z = the set of all f "(B.n) where n is Element of NAT;
    set Q = the set of all f "Y where Y is Element of (rng B) ;
    set E = Complement D;
    A2: for n be Element of NAT holds E.n = f "((Complement B).n)
    proof
      let n be Element of NAT;
      thus E.n = (D .n)` by PROB_1:def 2
      .= (f "(B.n))` by A1
      .= f " Omega2 \ (f "(B.n)) by FUNCT_2:40
      .= f " ((B.n)` ) by FUNCT_1:69
      .= f "((Complement B).n) by PROB_1:def 2;
    end;
    f"(Intersection B)=f"Omega2 \ f"(union rng (Complement B)) by FUNCT_1:69
    .=Omega1 \ f"(Union (Complement B)) by FUNCT_2:40
    .=Omega1 \ Union E by Th2,A2
    .=Omega1 \ union rng E;
    hence thesis;
  end;
