 reserve X for set;
 reserve S for Subset-Family of X;

theorem
  for X1,X2 be set,S1 be Subset-Family of X1,S2 be Subset-Family of X2 st
  S1 is cap-closed & S2 is cap-closed holds
  {s where s is Subset of [:X1,X2:]: ex x1,x2 be set st x1 in S1 & x2 in S2 &
  s=[:x1,x2:]} is cap-closed
  proof
    let X1,X2 be set, S1 be Subset-Family of X1,
    S2 be Subset-Family of X2;
    assume
A1: S1 is cap-closed;
    assume
A2: S2 is cap-closed;
    set Y= {s where s is Subset of [:X1,X2:]: ex
    x1,x2 be set st x1 in S1 & x2 in S2 & s=[:x1,x2:]};
    Y is cap-closed
    proof
      let W1,W2 be set;
      assume
A3:   W1 in Y;
      assume
A4:   W2 in Y;
      consider s1 be Subset of [:X1,X2:] such that
A5:   W1=s1 & ex xs1,xs2 be set st xs1 in S1 & xs2 in S2 &
      s1=[:xs1,xs2:] by A3;
      consider xs1,xs2 be set such that
A6:   xs1 in S1 & xs2 in S2 & s1=[:xs1,xs2:] by A5;
      consider s2 be Subset of [:X1,X2:] such that
A7:   W2=s2 & ex ys1,ys2 be set st ys1 in S1 & ys2 in S2 &
      s2=[:ys1,ys2:] by A4;
      consider ys1,ys2 be set such that
A8:   ys1 in S1 & ys2 in S2 & s2=[:ys1,ys2:] by A7;
A9:   [:xs1,xs2:]/\[:ys1,ys2:]=[:xs1/\ys1,xs2/\ys2:] by ZFMISC_1:100;
A10:  xs1/\ys1 in S1 & xs2/\ys2 in S2 by A6,A8,A1,A2,FINSUB_1:def 2;
      s1/\s2 in Y by A6,A8,A9,A10;
      hence thesis by A5,A7;
    end;
    hence thesis;
  end;
