reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th3:
  for f be c=-monotone Function-yielding Sequence
    for A be Ordinal,X be set st
        for o st o in X ex B be Ordinal st o in dom (f.B) & B in A
       holds
    (union rng (f|A)).:X = (union rng f).:X
proof
  let f be c=-monotone Function-yielding Sequence;
  let A be Ordinal,X be set such that
  A1:for x be object st x in X ex B be Ordinal st x in dom (f.B) & B in A;
  union rng (f|A) c= union rng f by ZFMISC_1:77;
  hence (union rng (f|A)).:X c= (union rng f).:X by RELAT_1:124;
  let y be object such that A2:y in (union rng f).:X;
  consider x be object such that
  A3: x in dom (union rng f) & x in X & (union rng f).x=y
    by A2,FUNCT_1:def 6;
  consider B be Ordinal such that
  A4:  x in dom (f.B) & B in A by A3,A1;
  A5: f.B<>{} by A4;
  then B in dom f by FUNCT_1:def 2;
  then A6: (f.B).x = (union rng f).x by A4,Th2;
  A7:(f|A).B = f.B by A4,FUNCT_1:49;
  then A8: B in dom (f|A) by A5,FUNCT_1:def 2;
  then A9: dom ((f|A).B) c= dom union rng (f|A) by Th2;
  y = (union rng (f|A)).x by A8,Th2,A7,A4,A3,A6;
  hence thesis by A9,A7,A4,A3,FUNCT_1:def 6;
end;
