reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;

theorem Th3:
  for L st 0<L & L<1 holds for s st 0<s ex n st L to_power n<s
proof
  let L such that
A1: 0<L & L<1;
  let s;
  deffunc U(Nat) = L to_power ($1+1);
  consider rseq being Real_Sequence such that
A2: for n being Nat holds rseq.n = U(n) from SEQ_1:sch 1;
  assume
A3: 0<s;
  rseq is convergent & lim rseq = 0 by A1,A2,SERIES_1:1;
  then consider n being Nat such that
A4: for m being Nat st n<=m holds |.rseq.m-0.|<s by A3,SEQ_2:def 7;
  take n+1;
A5: 0<L to_power (n+1) by A1,Th2;
  |.rseq.n-0.| = |.L to_power (n+1).| by A2
    .= L to_power (n+1) by A5,ABSVALUE:def 1;
  hence thesis by A4;
end;
