reserve T,T1,T2 for TopSpace,
  A,B for Subset of T,
  F for Subset of T|A,
  G,G1, G2 for Subset-Family of T,
  U,W for open Subset of T|A,
  p for Point of T|A,
  n for Nat,
  I for Integer;

theorem Th3:
  for F st F = B holds F in (Seq_of_ind T|A).n iff B in (Seq_of_ind T).n
proof
  defpred P[Nat] means for F be Subset of T|A,B st F=B holds F in (Seq_of_ind
  T|A).$1 iff B in (Seq_of_ind T).$1;
A1: for n st P[n] holds P[n+1]
  proof
    set TA=T|A;
    let n such that
A2: P[n];
    set n1=n+1;
    let F be Subset of TA,B such that
A3: F=B;
    set TAF=(T|A)|F;
    set TB=T|B;
A4: TAF=TB by A3,METRIZTS:9;
A5: [#]TB c=[#]T by PRE_TOPC:def 4;
    hereby
      assume
A6:   F in (Seq_of_ind TA).n1;
      per cases by A6,Def1;
      suppose
        F in (Seq_of_ind TA).n;
        then B in (Seq_of_ind T).n by A2,A3;
        hence B in (Seq_of_ind T).n1 by Def1;
      end;
      suppose
A7:     for p be Point of TAF,U be open Subset of TAF st p in U ex W
        be open Subset of TAF st p in W & W c=U & Fr W in (Seq_of_ind TA).n;
        now
          let p be Point of TB,U be open Subset of TB such that
A8:       p in U;
          reconsider U9=U as open Subset of TAF by A4;
          consider W9 be open Subset of TAF such that
A9:       p in W9 & W9 c=U9 & Fr W9 in (Seq_of_ind TA).n by A7,A8;
          reconsider W=W9 as open Subset of TB by A4;
          take W;
          Fr W is Subset of T by A5,XBOOLE_1:1;
          hence p in W & W c=U & Fr W in (Seq_of_ind T).n by A2,A4,A9;
        end;
        hence B in (Seq_of_ind T).n1 by Def1;
      end;
    end;
A10: [#]TAF c=[#]TA by PRE_TOPC:def 4;
    assume
A11: B in (Seq_of_ind T).n1;
    per cases by A11,Def1;
    suppose
      B in (Seq_of_ind T).n;
      then F in (Seq_of_ind TA).n by A2,A3;
      hence F in (Seq_of_ind TA).n1 by Def1;
    end;
    suppose
A12:  for p be Point of TB,U be open Subset of TB st p in U ex W be
      open Subset of TB st p in W & W c=U & Fr W in (Seq_of_ind T).n;
      now
        let p be Point of TAF,U be open Subset of TAF such that
A13:    p in U;
        reconsider U9=U as open Subset of TB by A4;
        consider W9 be open Subset of TB such that
A14:    p in W9 & W9 c=U9 & Fr W9 in (Seq_of_ind T).n by A12,A13;
        reconsider W=W9 as open Subset of TAF by A4;
        take W;
        Fr W is Subset of TA by A10,XBOOLE_1:1;
        hence p in W & W c=U & Fr W in (Seq_of_ind TA).n by A2,A4,A14;
      end;
      hence F in (Seq_of_ind TA).n1 by Def1;
    end;
  end;
A15: P[0]
  proof
A16: (Seq_of_ind T|A).0={{}(T|A)} by Def1
      .={{}T}
      .=(Seq_of_ind T).0 by Def1;
    let F be Subset of T|A,B;
    assume F=B;
    hence thesis by A16;
  end;
  for n holds P[n] from NAT_1:sch 2(A15,A1);
  hence thesis;
end;
