reserve x,y for set;
reserve s,s1,s2,s4,r,r1,r2 for Real;
reserve n,m,i,j for Element of NAT;

theorem Th3:
  for N, M being non empty MetrSpace, f being Function of
TopSpaceMetr(N),TopSpaceMetr(M) holds (for r being Real,u being Element
  of N,u1 being Element of M st r>0 & u1=f.u ex s being Real
 st s>0 & for w being Element of N, w1 being Element of M st w1=f.w &
  dist(u,w)<s holds dist(u1,w1)<r) implies f is continuous
proof
  let N,M be non empty MetrSpace,f be Function of TopSpaceMetr(N),
  TopSpaceMetr(M);
  dom f = the carrier of TopSpaceMetr(N) by FUNCT_2:def 1;
  then
A1: dom f=the carrier of N by TOPMETR:12;
  now
    assume
A2: for r being Real,u being Element of N,u1
    being Element of M st r>0 & u1=f.u ex s be Real st s>0 & for w being
Element of N, w1 being Element of M st w1=f.w & dist(u,w)<s holds dist(u1,w1)<r
    ;
    for r being Real,u being Element of M,P being
    Subset of TopSpaceMetr(M) st r>0 & P=Ball(u,r) holds f"P is open
    proof
      let r be Real,u be Element of M,P be Subset of
      TopSpaceMetr(M);
      reconsider P9=P as Subset of TopSpaceMetr(M);
      assume that
      r>0 and
A3:   P=Ball(u,r);
      for p being Point of N st p in f"P ex s being Real st s>0 &
      Ball(p,s) c= f"P
      proof
        let p be Point of N;
        assume p in f"P;
        then
A4:     f.p in Ball(u,r) by A3,FUNCT_1:def 7;
        then reconsider wf=f.p as Element of M;
        P9 is open by A3,TOPMETR:14;
        then consider r1 being Real such that
A5:     r1>0 and
A6:     Ball(wf,r1) c= P by A3,A4,TOPMETR:15;
        reconsider r1 as Real;
        consider s be Real such that
A7:     s>0 and
A8:     for w being Element of N, w1 being Element of M st w1=f.w &
        dist(p,w)<s holds dist(wf,w1)<r1 by A2,A5;
        reconsider s as Real;
        Ball(p,s) c= f"P
        proof
          let x be object;
          assume
A9:       x in Ball(p,s);
          then reconsider wx=x as Element of N;
          f.wx in rng f by A1,FUNCT_1:def 3;
          then reconsider wfx=f.wx as Element of M by TOPMETR:12;
          dist (p,wx)<s by A9,METRIC_1:11;
          then dist(wf,wfx)<r1 by A8;
          then wfx in Ball(wf,r1) by METRIC_1:11;
          hence thesis by A1,A6,FUNCT_1:def 7;
        end;
        hence thesis by A7;
      end;
      hence thesis by TOPMETR:15;
    end;
    hence f is continuous by JORDAN2B:16;
  end;
  hence thesis;
end;
