 reserve x,y,z for object,
   i,j,k,l,n,m for Nat,
   D,E for non empty set;
 reserve M for Matrix of D;
 reserve L for Matrix of E;

theorem
  for i being Nat st M = L & i in Seg width M
  holds Col(M,i) = Col(L,i)
  proof
    let i be Nat;
    assume AS1: M = L & i in Seg width M;
    A1: len (Col(M,i)) = len M
    & for j st j in dom M holds (Col(M,i)).j = M*(j,i) by MATRIX_0:def 8;
    A2: len (Col(L,i)) = len L
    & for j st j in dom L holds (Col(L,i)).j = L*(j,i) by MATRIX_0:def 8;
    A3: dom (Col(M,i)) = Seg len M by A1,FINSEQ_1:def 3
    .= dom (Col(L,i)) by AS1,A2,FINSEQ_1:def 3;
    for j st j in dom (Col(M,i))
    holds (Col(M,i)).j = (Col(L,i)).j
    proof
      let j;
      assume j in dom (Col(M,i));
      then j in Seg len M by FINSEQ_1:def 3,A1; then
      A4: j in dom M by FINSEQ_1:def 3;
      then [j,i] in Indices M by AS1,ZFMISC_1:87; then
      A5: M*(j,i) = L*(j,i) by AS1,EQ2;
      thus (Col(M,i)).j = M*(j,i) by A4,MATRIX_0:def 8
      .= (Col(L,i)).j by AS1,A4,A5,MATRIX_0:def 8;
    end;
    hence thesis by A3;
  end;
