
theorem :: Ex3a:
  for X being finite non empty set, F being Dependency-set of X, K being
  Subset of X st F = { [A, B] where A, B is Subset of X : K c= A or B c= A }
  holds {X}\/{B where B is Subset of X : not K c= B} = saturated-subsets F
proof
  let X be finite non empty set, F be Dependency-set of X, K being Subset of X;
  set BB = {X}\/{B where B is Subset of X : not K c= B};
  BB c= bool X
  proof
    let x be object;
    assume
A1: x in BB;
    per cases by A1,XBOOLE_0:def 3;
    suppose
A2:   x in {X};
      {X} c= bool X by ZFMISC_1:68;
      hence thesis by A2;
    end;
    suppose
      x in {B where B is Subset of X : not K c= B};
      then ex B being Subset of X st x = B & not K c= B;
      hence thesis;
    end;
  end;
  then reconsider BB9 = BB as non empty Subset-Family of X;
  set G = {[a, b] where a,b is Subset of X : for c being set st c in BB9 & a
  c= c holds b c= c};
A3: G = X deps_encl_by BB9;
A4: BB9 is (B2) by Th39;
  assume
A5: F = { [A, B] where A, B is Subset of X : K c= A or B c= A };
  now
    let x be object;
    hereby
      assume x in F;
      then consider a, b being Subset of X such that
A6:   x = [a,b] and
A7:   K c= a or b c= a by A5;
      now
        let c be set such that
A8:     c in BB9 and
A9:     a c= c;
        per cases by A7;
        suppose
A10:      K c= a;
          thus b c= c
          proof
            per cases by A8,XBOOLE_0:def 3;
            suppose
              c in {X};
              then c = X by TARSKI:def 1;
              hence thesis;
            end;
            suppose
              c in {B where B is Subset of X : not K c= B};
              then ex B being Subset of X st c = B & not K c= B;
              hence thesis by A9,A10;
            end;
          end;
        end;
        suppose
          b c= a;
          hence b c= c by A9;
        end;
      end;
      hence x in G by A6;
    end;
    assume x in G;
    then consider a, b being Subset of X such that
A11: x = [a,b] and
A12: for c being set st c in BB9 & a c= c holds b c= c;
    now
      assume not K c= a;
      then a in {B where B is Subset of X : not K c= B };
      then a in BB9 by XBOOLE_0:def 3;
      hence b c= a by A12;
    end;
    hence x in F by A5,A11;
  end;
  then
A13: F = G by TARSKI:2;
  BB9 is (B1) by Th39;
  hence thesis by A4,A3,A13,Th35;
end;
