reserve X for BCI-algebra;
reserve x,y,z for Element of X;
reserve i,j,k,l,m,n for Nat;
reserve f,g for sequence of the carrier of X;
reserve B,P for non empty Subset of X;

theorem
  for X being BCI-algebra st P = p-Semisimple-part(X) holds (X is
  BCK-algebra iff P = {0.X})
proof
  let X be BCI-algebra;
  assume
A1: P = p-Semisimple-part(X);
  thus X is BCK-algebra implies P = {0.X}
  proof
    assume
A2: X is BCK-algebra;
    thus P c= {0.X}
    proof
      let x be object;
      assume
A3:   x in P;
      then
A4:   ex x1 being Element of X st x=x1 & x1 is minimal by A1;
      reconsider x as Element of X by A1,A3;
      0.X\x = x` .= 0.X by A2,BCIALG_1:def 8;
      then x=0.X by A4;
      hence thesis by TARSKI:def 1;
    end;
    0.X in P by A1;
    then for x being object st x in {0.X} holds x in P by TARSKI:def 1;
    hence thesis;
  end;
  assume
A5: P = {0.X};
  for x being Element of X holds 0.X\x=0.X
  proof
    let x be Element of X;
    0.X in P by A5,TARSKI:def 1;
    then 0.X\x in P by A1,BCIALG_1:33;
    hence thesis by A5,TARSKI:def 1;
  end;
  then for x being Element of X holds x`=0.X;
  hence thesis by BCIALG_1:def 8;
end;
