
theorem Th40:
  for X be Complex_Banach_Algebra, z be Element of X holds
  ||.z.|| < 1 implies z GeoSeq is summable norm_summable
proof
  let X be Complex_Banach_Algebra;
  let z be Element of X;
A1: 0<= ||.z.|| by CLVECT_1:105;
A2: for n be Nat holds 0 <= ||.z GeoSeq.||.n & ||.z GeoSeq.||.n
  <=(||.z.|| GeoSeq).n
  proof
    defpred P[Nat] means
0 <= ||.z GeoSeq.||.$1 & ||.z GeoSeq.||.$1
    <= ( ||.z.|| GeoSeq ).$1;
A3: ||.(z GeoSeq).||.0 = ||.(z GeoSeq).0 .|| by NORMSP_0:def 4;
A4: for k be Nat st P[k] holds P[k+1]
    proof
      let k be Nat;
A5:   0 <= ||.z.|| by CLVECT_1:105;
      ||.(z GeoSeq.k)*z.|| <= ||.(z GeoSeq.k).||*||.z.|| by CLOPBAN2:def 9;
      then
A6:   ||. (z GeoSeq.k)*z .|| <= ||. z GeoSeq .||.k * ||.z.|| by NORMSP_0:def 4;
      assume P[k];
      then ||. z GeoSeq.||.k * ||.z.|| <= (||.z.|| GeoSeq ).k * ||.z.|| by A5,
XREAL_1:64;
      then
A7:   ||.
 (z GeoSeq.k)*z .|| <= ( ||.z.|| GeoSeq ).k * ||.z.|| by A6,XXREAL_0:2;
      ||.z GeoSeq.||.(k+1) = ||. (z GeoSeq).(k+1) .|| by NORMSP_0:def 4
        .= ||. (z GeoSeq).k * z .|| by Def4;
      hence thesis by A7,CLVECT_1:105,PREPOWER:3;
    end;
    ||.(z GeoSeq).0 .|| = ||.1.X.|| by Def4
      .= 1 by CLOPBAN2:def 10
      .= ( ||.z.|| GeoSeq ).0 by PREPOWER:3;
    then
A8: P[0] by A3,CLVECT_1:105;
    for n be Nat holds P[n] from NAT_1:sch 2(A8,A4);
    hence thesis;
  end;
  assume ||.z.|| < 1;
  then |. ||.z.||.| < 1 by A1,ABSVALUE:def 1;
  then ||.z.|| GeoSeq is summable by SERIES_1:24;
  then ||.z GeoSeq.|| is summable by A2,SERIES_1:20;
  then z GeoSeq is norm_summable;
  hence thesis;
end;
