
theorem Th40:
  for C1,C2 being Coherence_Space, f being U-stable Function of C1
  ,C2 for a being Element of C1, y being set holds y in f.a iff ex b being
  Element of C1 st [b,y] in Trace f & b c= a
proof
  let C1,C2 be Coherence_Space, f be U-stable Function of C1,C2;
  let a be Element of C1, y be set;
A1: dom f = C1 by FUNCT_2:def 1;
  hereby
    assume y in f.a;
    then consider b being set such that
    b is finite and
A2: b c= a and
A3: y in f.b and
A4: for c being set st c c= a & y in f.c holds b c= c by A1,Th22;
    reconsider b as Element of C1 by A2,CLASSES1:def 1;
    take b;
    now
      let c be set;
      assume that
      c in dom f and
A5:   c c= b and
A6:   y in f.c;
      c c= a by A2,A5;
      then b c= c by A4,A6;
      hence b = c by A5;
    end;
    hence [b,y] in Trace f by A1,A3,Th31;
    thus b c= a by A2;
  end;
  given b being Element of C1 such that
A7: [b,y] in Trace f and
A8: b c= a;
A9: y in f.b by A7,Th31;
  f.b c= f.a by A1,A8,Def11;
  hence thesis by A9;
end;
