
theorem help1:
for F being Field,
    E being FieldExtension of F
for T being finite Subset of E
holds T is F-algebraic implies FAdj(F,T) = RAdj(F,T)
proof
let F be Field, E be FieldExtension of F, T be finite Subset of E;
assume AS: T is F-algebraic;
  defpred P[Nat] means
    for F being Field, E being FieldExtension of F
    for T being finite Subset of E st card T = $1
    holds T is F-algebraic implies FAdj(F,T) = RAdj(F,T);
  A: P[0]
     proof
     now let F be Field, E be FieldExtension of F;
         let T be finite Subset of E;
       assume card T = 0; then
       T = {}; then
       A1: T is Subset of F by XBOOLE_1:2; then
       A2: FAdj(F,T) == F by FIELD_7:3;
       F == RAdj(F,T) by A1,helpa;
       hence FAdj(F,T) = RAdj(F,T) by A2,helpb,FIELD_7:2;
       end;
     hence thesis;
     end;
  B: now let k be Nat;
     assume B0: P[k];
     now let F be Field, E be FieldExtension of F;
         let T be finite Subset of E;
       assume C0: card T = k + 1;
       assume T is F-algebraic; then
       reconsider T1 = T as non empty finite F-algebraic Subset of E by C0;
       set a = the Element of T1;
       reconsider a as F-algebraic Element of E;
       reconsider T2 = T1 \ {a} as finite F-algebraic Subset of E;
           a in T1; then
           {a} c= T1 by TARSKI:def 1; then
       C4: T1 = T2 \/ {a} by XBOOLE_1:45;
           a in {a} by TARSKI:def 1; then
           not a in T2 by XBOOLE_0:def 5; then
           card T1 = card T2 + 1 by C4,CARD_2:41; then
       C6: FAdj(F,T2) = RAdj(F,T2) by B0,C0;
       reconsider E1 = E as FieldExtension of FAdj(F,T2) by FIELD_4:7;
       reconsider a1 = a as Element of E1;
       reconsider E2 = E1 as RingExtension of RAdj(F,T2) by FIELD_4:def 1;
       reconsider a2 = a1 as Element of E2;
       C7: a1 is FAdj(F,T2)-algebraic
           proof
           consider p being non zero Polynomial of F such that
           C8: Ext_eval(p,a) = 0.E by FIELD_6:43;
               p <> 0_.F; then
           C9: p <> 0.(Polynom-Ring F) by POLYNOM3:def 10;
           reconsider p as non zero Element of the carrier of Polynom-Ring F
               by POLYNOM3:def 10;
               the carrier of Polynom-Ring F
                  c= the carrier of Polynom-Ring FAdj(F,T2) by FIELD_4:10; then
           reconsider q = p as
                        Element of the carrier of Polynom-Ring FAdj(F,T2);
           now assume q is zero;
               then q = 0_.FAdj(F,T2) by UPROOTS:def 5;
               then q = 0.(Polynom-Ring FAdj(F,T2)) by POLYNOM3:def 10;
               hence contradiction by C9,FIELD_4:11;
               end; then
           reconsider q as
              non zero Element of the carrier of Polynom-Ring FAdj(F,T2);
           E1 is FAdj(F,T2)-extending FieldExtension of F; then
           Ext_eval(q,a) = Ext_eval(p,a) by FIELD_7:15;
           hence thesis by C8,FIELD_6:43;
           end;
       FAdj(F,{a}\/T2) = FAdj(FAdj(F,T2),{a1}) by FIELD_7:34
           .= RAdj(RAdj(F,T2),{a2}) by C6,C7,FIELD_6:56
           .= RAdj(F,{a}\/T2) by ug;
       hence FAdj(F,T) = RAdj(F,T) by C4;
       end;
     hence P[k+1];
     end;
  I: for k being Nat holds P[k] from NAT_1:sch 2(A,B);
  consider n being Nat such that H: card T = n;
  thus FAdj(F,T) = RAdj(F,T) by AS,H,I;
end;
