
theorem Th40:
  for F1, F2, F3 being Graph-yielding Function
  st F1, F2 are_Disomorphic & F2, F3 are_Disomorphic
  holds F1, F3 are_Disomorphic
proof
  let F1, F2, F3 be Graph-yielding Function;
  assume F1, F2 are_Disomorphic;
  then consider p being one-to-one Function such that
    A1: dom p = dom F1 & rng p = dom F2 and
    A2: for x being object st x in dom F1 ex G1, G2 being _Graph
      st G1 = F1.x & G2 = F2.(p.x) & G2 is G1-Disomorphic;
  assume F2, F3 are_Disomorphic;
  then consider q being one-to-one Function such that
    A3: dom q = dom F2 & rng q = dom F3 and
    A4: for x being object st x in dom F2 ex G2, G3 being _Graph
      st G2 = F2.x & G3 = F3.(q.x) & G3 is G2-Disomorphic;
  take q*p;
  dom(q*p) = dom p & rng(q*p) = rng q by A1, A3, RELAT_1:27, RELAT_1:28;
  hence A5: dom(q*p) = dom F1 & rng(q*p) = dom F3 by A1, A3;
  let x be object;
  assume x in dom F1;
  then A6: x in dom p & p.x in dom q by A5, FUNCT_1:11;
  then consider G1, G2 be _Graph such that
    A7: G1 = F1.x & G2 = F2.(p.x) & G2 is G1-Disomorphic by A1, A2;
  consider G9,G3 being _Graph such that
    A8: G9 = F2.(p.x) & G3 = F3.(q.(p.x)) & G3 is G9-Disomorphic by A3, A4, A6;
  take G1, G3;
  thus G1 = F1.x by A7;
  thus G3 = F3.((q*p).x) by A6, A8, FUNCT_1:13;
  thus thesis by A7, A8;
end;
