reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th40:
  1 <= i & i < len G & 1 <= j & j < width G implies LSeg(1/2*(G*(i
,j)+G*(i+1,j+1)),1/2*(G*(i,j)+G*(i,j+1))) c= Int cell(G,i,j) \/ { 1/2*(G*(i,j)+
  G*(i,j+1)) }
proof
  assume that
A1: 1 <= i and
A2: i < len G and
A3: 1 <= j and
A4: j < width G;
  let x be object;
  assume
A5: x in LSeg(1/2*(G*(i,j)+G*(i+1,j+1)),1/2*(G*(i,j)+G*(i,j+1)));
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A6: p = (1-r)*(1/2*(G*(i,j)+G*(i+1,j+1)))+r*(1/2*(G*(i,j)+G*(i,j+1))) and
A7: 0<=r and
A8: r<=1 by A5;
  now
    per cases by A8,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(1/2*(G*(i,j)+G*(i,j+1))) by A6,RLVECT_1:10

        .= 1*(1/2*(G*(i,j)+G*(i,j+1))) by RLVECT_1:4
        .= 1/2*(G*(i,j)+G*(i,j+1)) by RLVECT_1:def 8;
      hence p in { 1/2*(G*(i,j)+G*(i,j+1)) } by TARSKI:def 1;
    end;
    case
A9:   r < 1;
      set r3 = (1-r)*(1/2), s3 = r*(1/2);
      set r1 = G*(i,1)`1, r2 = G*(i+1,1)`1, s1 = G*(1,j)`2, s2 = G*(1,j+1)`2;
A10:  r3*(s1+s1)+s3*(s1+s1) = s1;
      0 <> len G by MATRIX_0:def 10;
      then
A11:  1 <= len G by NAT_1:14;
A12:  j+1 <= width G by A4,NAT_1:13;
      j < j+1 by XREAL_1:29;
      then
A13:  s1 < s2 by A3,A12,A11,GOBOARD5:4;
      then
A14:  s1+s1 < s1+s2 by XREAL_1:6;
      then
A15:  s3*(s1+s1) <= s3*(s1+s2) by A7,XREAL_1:64;
      1 - r > 0 by A9,XREAL_1:50;
      then
A16:  r3 > (1/2)*0 by XREAL_1:68;
      then r3*(s1+s1) < r3*(s1+s2) by A14,XREAL_1:68;
      then
A17:  s1 < r3*(s1+s2)+s3*(s1+s2) by A15,A10,XREAL_1:8;
A18:  s1+s2 < s2+s2 by A13,XREAL_1:6;
      then
A19:  s3*(s1+s2) <= s3*(s2+s2) by A7,XREAL_1:64;
      0 <> width G by MATRIX_0:def 10;
      then
A20:  1 <= width G by NAT_1:14;
A21:  1 <= i+1 by A1,NAT_1:13;
A22:  Int cell(G,i,j) = { |[r9,s9]| : r1 < r9 & r9 < r2 & s1 < s9 & s9 <
      s2 } by A1,A2,A3,A4,Th26;
A23:  1 <= j+1 by A3,NAT_1:13;
A24:  G*(i,j+1) = |[G*(i,j+1)`1,G*(i,j+1)`2]| by EUCLID:53
        .= |[r1,G*(i,j+1)`2]| by A1,A2,A23,A12,GOBOARD5:2
        .= |[r1,s2]| by A1,A2,A23,A12,GOBOARD5:1;
A25:  r3*(s2+s2)+s3*(s2+s2) = s2;
      r3*(s1+s2) < r3*(s2+s2) by A16,A18,XREAL_1:68;
      then
A26:  r3*(s1+s2)+s3*(s1+s2) < s2 by A19,A25,XREAL_1:8;
A27:  i+1 <= len G by A2,NAT_1:13;
      i < i+1 by XREAL_1:29;
      then
A28:  r1 < r2 by A1,A27,A20,GOBOARD5:3;
      then r1+r1 < r2+r2 by XREAL_1:8;
      then
A29:  s3*(r1+r1) <= s3*(r2+r2) by A7,XREAL_1:64;
      r1+r2 < r2+r2 by A28,XREAL_1:6;
      then
A30:  r3*(r1+r2) < r3*(r2+r2) by A16,XREAL_1:68;
      r3*(r2+r2)+s3*(r2+r2) = r2;
      then
A31:  r3*(r1+r2)+s3*(r1+r1) < r2 by A30,A29,XREAL_1:8;
A32:  G*(i,j) = |[G*(i,j)`1,G*(i,j)`2]| by EUCLID:53
        .= |[r1,G*(i,j)`2]| by A1,A2,A3,A4,GOBOARD5:2
        .= |[r1,s1]| by A1,A2,A3,A4,GOBOARD5:1;
A33:  G*(i+1,j+1) = |[G*(i+1,j+1)`1,G*(i+1,j+1)`2]| by EUCLID:53
        .= |[r2,G*(i+1,j+1)`2]| by A23,A12,A21,A27,GOBOARD5:2
        .= |[r2,s2]| by A23,A12,A21,A27,GOBOARD5:1;
A34:  r3*(r1+r1)+s3*(r1+r1) = r1;
      r1+r1 < r1+r2 by A28,XREAL_1:6;
      then r3*(r1+r1) < r3*(r1+r2) by A16,XREAL_1:68;
      then
A35:  r1 < r3*(r1+r2)+s3*(r1+r1) by A34,XREAL_1:6;
      p = r3*(G*(i,j)+G*(i+1,j+1))+r*(1/2*(G*(i,j)+G* (i,j+1))) by A6,
RLVECT_1:def 7
        .= r3*(G*(i,j)+G*(i+1,j+1))+s3*(G*(i,j)+G*(i,j+1)) by RLVECT_1:def 7
        .= r3*|[r1+r2,s1+s2]|+s3*(G*(i,j)+G*(i,j+1)) by A32,A33,EUCLID:56
        .= r3*|[r1+r2,s1+s2]|+s3*|[r1+r1,s1+s2]| by A32,A24,EUCLID:56
        .= |[r3*(r1+r2),r3*(s1+s2)]|+s3*|[r1+r1,s1+s2]| by EUCLID:58
        .= |[r3*(r1+r2),r3*(s1+s2)]|+|[s3*(r1+r1),s3*(s1+s2)]| by EUCLID:58
        .= |[r3*(r1+r2)+s3*(r1+r1),r3*(s1+s2)+s3*(s1+s2)]| by EUCLID:56;
      hence p in Int cell(G,i,j) by A35,A31,A17,A26,A22;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
