
theorem

:: Polarization Formulae
  for V be VectSp of F_Complex, v,w be Vector of V, f be hermitan-Form
of V holds f.(v,w) + f.(v,w) + f.(v,w) + f.(v,w) = f.(v+w,v+w) - f.(v-w,v-w) +
  i_FC *f.(v+i_FC*w,v+i_FC*w) -i_FC *f.(v-i_FC*w,v-i_FC*w)
proof
  let V be VectSp of F_Complex, v1,w be Vector of V, f be hermitan-Form of V;
  set v3 = f.(v1,v1), v4 = f.(v1,w), w2 = f.(w,w), w1 = f.(w,v1);
  f.(v1+w,v1+w) = v3 +v4 + (w1 + w2) & f.(v1-w,v1-w) = v3 - v4 - (w1 - w2)
  by Th36,BILINEAR:28;
  then
A1: f.(v1+w,v1+w) - f.(v1-w,v1-w) = v3 + v4 - (v3 - v4 - (w1 - w2)) + (w1 + w2)
    .= (v3 + v4 - (v3 - v4)) + (w1 - w2) + (w1 + w2) by RLVECT_1:29
    .= (v3 - (v3 - v4) + v4) + (w1 - w2) + (w1 + w2)
    .= (v3 - v3 + v4 + v4) + (w1 - w2) + (w1 + w2) by RLVECT_1:29
    .= ((0.F_Complex) + v4 + v4) + (w1 - w2) + (w1 + w2) by RLVECT_1:15
    .= (v4 + v4) + (w1 - w2) + (w1 + w2) by RLVECT_1:def 4
    .= (v4 + v4) + (w1 - w2 + w2 + w1)
    .= (v4 + v4) + (w1 - (w2 - w2) + w1) by RLVECT_1:29
    .= (v4 + v4) + (w1 - (0.F_Complex) + w1) by RLVECT_1:15
    .= (v4 + v4) + (w1 + w1) by RLVECT_1:13;
  f.(v1+i_FC * w,v1 + i_FC * w) = v3 + i_FC*' * v4 + (i_FC* w1 + i_FC*(
  i_FC*' * w2)) by Th37
    .= v3 + i_FC*' * v4 + i_FC*(w1 + i_FC*' * w2);
  then
A2: i_FC *f.(v1+i_FC*w,v1+i_FC*w) = i_FC * (v3 + i_FC*' * v4)+ i_FC*i_FC*(w1
  + i_FC*' * w2)
    .= i_FC * v3 + v4 -(w1 + i_FC*' * w2) by COMPLEX1:7,HAHNBAN1:4,VECTSP_6:48;
  f.(v1-i_FC * w,v1 - i_FC * w) = f.(v1,v1-i_FC*w) - f.(i_FC*w,v1-i_FC*w)
  by BILINEAR:35
    .= v3 - f.(v1,i_FC*w) - f.(i_FC*w,v1-i_FC*w) by Th35
    .= v3 - i_FC*' * v4 - f.(i_FC*w,v1-i_FC*w) by Th27
    .= v3 - i_FC*' * v4 - i_FC*f.(w,v1-i_FC*w) by BILINEAR:31
    .= v3 - i_FC*' * v4 - i_FC*(w1 - f.(w,i_FC*w)) by Th35
    .= v3 - i_FC*' * v4 - i_FC*(w1 - i_FC*' * w2) by Th27;
  then
  i_FC *f.(v1-i_FC*w,v1-i_FC*w) = i_FC * (v3 - i_FC*' * v4)- i_FC*(i_FC*(
  w1 - i_FC*' * w2)) by VECTSP_1:11
    .= i_FC * (v3 - i_FC*' * v4)- i_FC*i_FC*(w1 - i_FC*' * w2)
    .= i_FC * (v3 - i_FC*' * v4)- -(w1 - i_FC*' * w2) by HAHNBAN1:4,VECTSP_6:48
    .= i_FC * (v3 - i_FC*' * v4) +(w1 - i_FC*' * w2) by COMPLFLD:11
    .= i_FC * v3 - i_FC *(i_FC*' * v4) +(w1 - i_FC*' * w2) by VECTSP_1:11
    .= i_FC * v3 - v4 +(w1 - i_FC*' * w2) by COMPLEX1:7;
  then i_FC *f.(v1+i_FC*w,v1+i_FC*w) - i_FC *f.(v1-i_FC*w,v1-i_FC*w) = i_FC *
  v3 + v4 -(w1 + i_FC*' * w2) - (i_FC * v3 - v4) - (w1 - i_FC*' * w2) by A2,
RLVECT_1:27
    .= i_FC * v3 + v4 - (i_FC * v3 - v4) -(w1 + i_FC*' * w2) - (w1 - i_FC*'
  * w2)
    .= v4 + i_FC * v3 - i_FC * v3 + v4 -(w1 + i_FC*' * w2) - (w1 - i_FC*' *
  w2) by RLVECT_1:29
    .= v4 + (i_FC * v3 - i_FC * v3) + v4 -(w1 + i_FC*' * w2) - (w1 - i_FC*'
  * w2)
    .= v4 + (0.F_Complex) + v4 -(w1 + i_FC*' * w2) - (w1 - i_FC*' * w2) by
RLVECT_1:15
    .= v4 + v4 -(w1 + i_FC*' * w2) - (w1 - i_FC*' * w2) by RLVECT_1:def 4
    .= v4 + v4 -(w1 + i_FC*' * w2 + (w1 - i_FC*' * w2)) by RLVECT_1:27
    .= v4 + v4 -(w1 + w1 + (i_FC*' * w2 - i_FC*' * w2))
    .= v4 + v4 -(w1 + w1 + 0.F_Complex) by RLVECT_1:15
    .= v4 + v4 -(w1 + w1) by RLVECT_1:def 4;
  then
  f.(v1+w,v1+w) - f.(v1-w,v1-w) +i_FC *f.(v1+i_FC*w,v1+i_FC*w) -i_FC *f.(
  v1-i_FC*w,v1-i_FC*w) = v4 + v4 + (w1 + w1 + (v4 + v4) -(w1 + w1)) by A1
    .= v4 + v4 + (v4 + v4) by COMPLFLD:12
    .= v4 + v4 + v4 + v4;
  hence thesis;
end;
