
theorem Th40:
  for X be Banach_Algebra for z be Element of X holds ||.z.|| < 1
  implies z GeoSeq is summable norm_summable
proof
  let X be Banach_Algebra;
  let z be Element of X;
A1: for n be Nat holds 0 <= ||.z GeoSeq.||.n & ||.z GeoSeq.||.n
  <=(||.z.|| GeoSeq).n
  proof
    defpred P[Nat] means
0 <= ||.z GeoSeq.||.$1 & ||.z GeoSeq.||.$1
    <= ( ||.z.|| GeoSeq ).$1;
A2: ||.(z GeoSeq).||.0 = ||.(z GeoSeq).0 .|| by NORMSP_0:def 4;
A3: for k be Nat st P[k] holds P[k+1]
    proof
      let k be Nat;
      ||. (z GeoSeq.k)*z .|| <= ||. (z GeoSeq.k) .|| * ||.z.|| by
LOPBAN_2:def 9;
      then
A4:   ||. (z GeoSeq.k)*z .|| <= ||. z GeoSeq .||.k * ||.z.||
                by NORMSP_0:def 4;
      assume P[k];
      then ||. z GeoSeq.||.k * ||.z.|| <= ( ||.z.|| GeoSeq ).k * ||.z.|| by
XREAL_1:64;
      then
A5:   ||.
 (z GeoSeq.k)*z .|| <= ( ||.z.|| GeoSeq ).k * ||.z.|| by A4,XXREAL_0:2;
      ||.z GeoSeq.||.(k+1) = ||. (z GeoSeq).(k+1) .|| by NORMSP_0:def 4
        .= ||. (z GeoSeq).k * z .|| by Def9;
      hence thesis by A5,PREPOWER:3;
    end;
    ||.(z GeoSeq).0 .|| = ||.1.X.|| by Def9
      .= 1 by LOPBAN_2:def 10
      .= ( ||.z.|| GeoSeq ).0 by PREPOWER:3;
    then
A6: P[0] by A2;
    for n be Nat holds P[n] from NAT_1:sch 2(A6,A3);
    hence thesis;
  end;
  assume ||.z.|| < 1;
  then |. ||.z.||.| < 1 by ABSVALUE:def 1;
  then ||.z.|| GeoSeq is summable by SERIES_1:24;
  then ||.z GeoSeq.|| is summable by A1,SERIES_1:20;
  then z GeoSeq is norm_summable;
  hence thesis;
end;
