reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);
reserve D for non empty set,
  bD for FinSequence of D,
  b,f,g for FinSequence of K,
  MD for Matrix of D;

theorem Th40:
  j in Seg m & (i = j implies a <> -1_K) implies Solutions_of(A9,
B9) = Solutions_of(RLine(A9,i,Line(A9,i) + a*Line(A9,j)), RLine(B9,i,Line(B9,i)
  + a*Line(B9,j)))
proof
  assume that
A1: j in Seg m and
A2: i = j implies a <> -1_K;
  per cases;
  suppose
    i<>j;
    hence thesis by A1,Lm5;
  end;
  suppose
A3: i=j;
A4: 1_K+a <> 0.K
    proof
      assume 1_K+a=0.K;
      then -1.K = -1.K+(1_K+a) by RLVECT_1:def 4
        .= (-1.K+1_K)+a by RLVECT_1:def 3
        .= 0.K+a by VECTSP_1:19
        .= a by RLVECT_1:def 4;
      hence thesis by A2,A3;
    end;
    set LB=Line(B9,i);
    set LA=Line(A9,i);
A5: LB+a*LB = 1_K*LB+a*LB by FVSUM_1:57
      .= (1_K+a)*LB by FVSUM_1:55;
    LA+a*LA = 1_K*LA+a*LA by FVSUM_1:57
      .= (1_K+a)*LA by FVSUM_1:55;
    hence thesis by A3,A4,A5,Lm4;
  end;
end;
