reserve a,a1,a2,v,v1,v2,x for object;
reserve V,A for set;
reserve m,n for Nat;
reserve S,S1,S2 for FinSequence;
reserve D,D1,D2 for NonatomicND of V,A;

theorem
  ND(V,A) = Union FNDSC(V,A)
  proof
    set F = FNDSC(V,A);
    thus ND(V,A) c= Union F
    proof
      let x;
      assume x in ND(V,A);
      then x is TypeSCNominativeData of V,A by Th39;
      then
A1:   x in A or x is NonatomicND of V,A by Def6;
      A c= Union F by Th11;
      hence thesis by A1,Th31;
    end;
    let x;
    assume x in Union F;
    then consider z being object such that
A2: z in dom F and
A3: x in F.z by CARD_5:2;
    reconsider z as Element of NAT by A2,Def3;
    per cases;
    suppose z = 0;
      then x in A by A3,Def3;
      then x is TypeSCNominativeData of V,A by Def6;
      hence thesis;
    end;
    suppose
A4:   z <> 0;
      then
A5:   1 <= z by NAT_1:14;
      reconsider n = z-1 as Element of NAT by A4,INT_1:5,NAT_1:14;
A6:   dom F = NAT by Def3;
      set S = F|Seg(z);
      F.(n+1) = NDSS(V,A\/F.n) by Def3;
      then
A7:   x is TypeSSNominativeData of V,A\/F.n by A3,Th4;
A8:   dom S = Seg(z) by A6,RELAT_1:62;
A9:   z in Seg(z) by A5;
      then S.z = F.z by FUNCT_1:49;
      then F.z in rng S by A8,A9,FUNCT_1:def 3;
      then x in Union S by A3,TARSKI:def 4;
      then x is NonatomicND of V,A by A7,A5,Th18,Def5;
      hence thesis;
    end;
  end;
