reserve n for Nat,
  a,b for Real,
  s for Real_Sequence;

theorem
  (for n holds s.n = (n*2|^n)/((n+2)!)) implies for n st n>=1 holds
  Partial_Sums(s).n = 1-2|^(n+1)/((n+2)!)
proof
  defpred X[Nat] means Partial_Sums(s).$1=1-2|^($1+1)/(($1+2)!);
  assume
A1: for n holds s.n = (n*2|^n)/((n+2)!);
  then
A2: s.0=(0*2|^0)/((0+2)!) .=0;
A3: for n be Nat st n>=1 & X[n] holds X[n+1]
  proof
    let n be Nat;
    assume that
    n>=1 and
A4: Partial_Sums(s).n =1-2|^(n+1)/((n+2)!);
    n+3>=3 by NAT_1:11;
    then
A5: n+3>0 by XXREAL_0:2;
    Partial_Sums(s).(n+1)=1-2|^(n+1)/((n+2)!)+ s.(n+1) by A4,
SERIES_1:def 1
      .=1-2|^(n+1)/((n+2)!)+((n+1)*2|^(n+1))/((n+1+2)!) by A1
      .=1-(2|^(n+1)*(n+3))/((n+2)!*(n+2+1))+((n+1)*2|^(n+1))/((n+3)!) by A5,
XCMPLX_1:91
      .=1-(2|^(n+1)*(n+3))/((n+2+1)!)+((n+1)*2|^(n+1))/((n+3)!) by NEWTON:15
      .=1-((2|^(n+1)*(n+3))/((n+2+1)!)-((n+1)*2|^(n+1))/((n+3)!))
      .=1-(2|^(n+1)*(n+3)-2|^(n+1)*(n+1))/((n+3)!) by XCMPLX_1:120
      .=1-(2|^(n+1)*2)/((n+3)!)
      .=1-2|^(n+1+1)/((n+1+2)!) by NEWTON:6;
    hence thesis;
  end;
  Partial_Sums(s).(1+0)=Partial_Sums(s).0+s.(1+0) by SERIES_1:def 1
    .= s.0 + s.1 by SERIES_1:def 1
    .=(1*2|^1)/((1+2)!) by A1,A2
    .=2/((2+1)!)
    .=2/(2*3) by NEWTON:14,15
    .=1-(2*2)/(2!*(2+1)) by NEWTON:14
    .=1-2|^2/(2!*(2+1)) by WSIERP_1:1
    .=1-2|^(1+1)/((1+2)!) by NEWTON:15;
  then
A6: X[1];
  for n be Nat st n>=1 holds X[n] from NAT_1:sch 8(A6,A3);
  hence thesis;
end;
