reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th40:
  -(x+y) = -x + -y
proof
  defpred P[Ordinal] means
  for x,y be Surreal st born x (+) born y c= $1 holds - (x + y) = -x + -y;
  A1: for D be Ordinal st for C be Ordinal st C in D holds P[C] holds P[D]
  proof
    let D be Ordinal such that A2: for C be Ordinal st C in D holds P[C];
    A3: for x,y be Surreal st born x (+) born y c= D
    for X,Y be surreal-membered set
    st (X c= L_x\/R_x & Y={y}) or (Y c= L_y\/R_y & X={x})
    holds -- (X ++ Y) = (--X) ++ (--Y)
    proof
      let x,y be Surreal such that A4: born x (+) born y c= D;
      let X,Y be surreal-membered set such that
      A5:(X c= L_x\/R_x & Y={y}) or (Y c= L_y\/R_y & X={x});
      thus -- (X ++ Y) c= (--X) ++ (--Y)
      proof
        let a be object;
        assume a in -- (X ++ Y);
        then consider  z be Surreal such that
        A6:z in (X ++ Y) & a=-z by Def4;
        consider x1,y1 be Surreal such that
        A7: x1 in X & y1 in Y & z=x1+y1 by A6,Def8;
        (born x1 in born x & born y1 = born y) or
        (born x1=born x & born y1 in born y) by SURREALO:1,A5,A7,TARSKI:def 1;
        then born x1 (+) born y1 in born x(+) born y by ORDINAL7:94;
        then A8: a = (-x1) + (-y1) by A2,A4,A6,A7;
        -x1 in --X & -y1 in --Y by A7,Def4;
        hence thesis by A8,Def8;
      end;
      let a be object;
      assume a in (--X) ++ (--Y);
      then consider x2,y2 be Surreal such that
      A9: x2 in --X & y2 in --Y & a=x2+y2 by Def8;
      consider x1 be Surreal such that
      A10: x1 in X & x2=-x1 by A9,Def4;
      consider y1 be Surreal such that
      A11: y1 in Y & y2=-y1 by A9,Def4;
      A12: x1+y1 in X ++ Y by A10,A11,Def8;
      (born x1 in born x & born y1 = born y) or
      (born x1=born x & born y1 in born y)
      by SURREALO:1,A5,A10,A11,TARSKI:def 1;
      then born x1 (+) born y1 in born x(+) born y by ORDINAL7:94;
      then -(x1+y1) = a by A2,A4,A10,A11,A9;
      hence thesis by A12,Def4;
    end;
    let x,y be Surreal such that A13: born x (+) born y c= D;
    A14:L_x c= L_x\/R_x by XBOOLE_1:7;
    A15:R_x c= L_x\/R_x by XBOOLE_1:7;
    A16:L_y c= L_y\/R_y by XBOOLE_1:7;
    A17:R_y c= L_y\/R_y by XBOOLE_1:7;
    A18: x + y = [(L_x ++ {y})\/({x}++L_y), (R_x ++ {y}) \/({x}++R_y)]
    by Th28;
    A19:  L_(-x) = --R_x & R_(-x) = --L_x & (-y)`1 = --R_y & (-y)`2 = --L_y
    by Th8;
    A20:{-x} = --{x} & {-y} = --{y} by Th21;
    A21: R_(-x) ++ {-y}  = --(L_x ++{y}) by A19,A20, A14,A3,A13;
    A22: {-x}++R_(-y) =--({x}++ L_y) by A19,A20,A16,A3,A13;
    A23: L_(-x) ++ {-y} = --(R_x ++{y}) by A19,A20,A15,A3,A13;
    {-x}++L_(-y) =--({x}++ R_y) by A19,A20,A17,A3,A13;
    then A24: (L_(-x) ++ {-y})\/({-x}++L_(-y)) =
    -- ((R_x ++{y})\/({x}++ R_y)) by A23,Th20;
    thus -x + -y = [(L_(-x) ++ {-y})\/({-x}++L_(-y)),
    (R_(-x) ++ {-y}) \/({-x}++R_(-y))] by Th28
    .= [-- R_(x+y), -- L_(x+y)] by A18,A22,A21,Th20,A24
    .= - (x+y) by Th7;
  end;
  for D be Ordinal holds P[D] from ORDINAL1:sch 2(A1);
  hence thesis;
end;
