
theorem :: Theorem 4:69
  for R being connected non empty Poset
  st R is well_founded holds FinPoset R is well_founded
proof
  let R be connected non empty Poset such that
A1: R is well_founded;
  set IR = the InternalRel of R, CR = the carrier of R;
  set FIR = FinOrd R, FCR = Fin CR;
  assume not FinPoset R is well_founded;
  then consider A being sequence of FinPoset R such that
A2: A is descending by WELLFND1:14;
  set zz = {z where z is sequence of FinPoset R : z is descending};
  A in zz by A2;
  then reconsider zz as non empty set;
  set Z = [: CR, zz :];
  defpred S[Nat,set,set] means ex Sn2 being sequence of FinPoset R,
  Smax being sequence of  CR, an being Element of R,
  ix being Nat, bnt being sequence of FinPoset R,
  bn being sequence of FinPoset R st Sn2 = ($2)`2 &
  (for i being Nat holds
  ex Sn2i being Element of Fin CR st Sn2i = Sn2.i & Sn2i <> {} &
  Smax.i = PosetMax Sn2i) & an = MinElement(rng Smax, R) &
  ix = Smax mindex an & bnt = Sn2^\ix &
  (for i being Nat holds bn.i = bnt.i \ {an}) &
  (for i being Nat st ix <= i holds Smax.i = an) & $3 = [an,bn];
A3: for n being Nat for Sn being Element of Z
  ex Sn1 being Element of Z st S[n,Sn,Sn1]
  proof
    let n being Nat, Sn be Element of Z;
    set Sn2 = Sn`2;
    Sn2 in zz;
    then
A4: ex z being sequence of FinPoset R st ( z = Sn2)&( z is descending);
    then reconsider Sn2 as sequence of FinPoset R;
A5: now
      let i be Nat;
      assume
A6:   Sn2.i = {};
A7:   Sn2.(i+1)<>Sn2.i by A4;
      [Sn2.(i+1), Sn2.i] in FIR by A4;
      hence contradiction by A6,A7,Th33;
    end;
    defpred P[Nat,set] means
    (ex Sn2i being Element of Fin CR st Sn2i = Sn2.$1 &
    Sn2i <> {} & $2 = PosetMax Sn2i);
A8: for i being Element of NAT ex y being Element of CR st P[i,y]
    proof
      let i be Element of NAT;
      set Sn2i = Sn2.i;
      reconsider Sn2i as Element of Fin CR;
      set y = PosetMax Sn2i;
      take y;
      take Sn2i;
      thus Sn2i = Sn2.i;
      thus Sn2i <> {} by A5;
      thus thesis;
    end;
    consider Smax being sequence of  CR such that
A9: for i being Element of NAT holds P[i,Smax.i] from FUNCT_2:sch 3(A8);
    set an = MinElement(rng Smax, R);
    set ix = Smax mindex an;
    set bnt = Sn2^\ix;
    defpred R[set,set] means
    (ex bni being Element of FCR st bni = bnt.$1 \{an} & $2 = bni);
    now
      let i be Nat;
      set bni = bnt.i \ {an};
      reconsider k = bnt.i as finite Subset of CR by FINSUB_1:def 5;
      k \ {an} in FCR by FINSUB_1:def 5;
      then reconsider bni as Element of FCR;
      set y = bni;
      take y;
      take bni;
      thus bni = bnt.i \ {an};
      thus y = bni;
    end;
    then
A10: for i being Element of NAT ex y being Element of FCR st R[i,y];
    defpred P[Nat] means Smax.(ix+$1) = an;
A11: dom Smax = NAT by FUNCT_2:def 1;
A12: rng Smax c= CR by RELAT_1:def 19;
    then
A13: an in rng Smax by A1,Def17;
A14: an is_minimal_wrt rng Smax, IR by A1,A12,Def17;
A15: P[ 0 ] by A11,A13,DICKSON:def 11;
A16: now
      let k be Nat such that
A17:  P[k];
      reconsider ixk = ix+k as Element of NAT by ORDINAL1:def 12;
      set ixk1 = ix+(k+1), ixk19 = (ix+k)+1;
      consider Sn2ixk being Element of Fin CR such that
A18:  Sn2ixk = Sn2.ixk and Sn2ixk <> {} and
A19:  Smax.ixk = PosetMax Sn2ixk by A9;
      consider Sn2ixk1 being Element of Fin CR such that
A20:  Sn2ixk1 = Sn2.ixk1 and
A21:  Sn2ixk1 <> {} and
A22:  Smax.ixk1 = PosetMax Sn2ixk1 by A9;
      reconsider Sn2ixk9 = Sn2ixk, Sn2ixk19 = Sn2ixk1 as
      Element of FinPoset R;
      ixk1 = ixk19;
      then [Sn2ixk19, Sn2ixk9] in FIR by A4,A18,A20;
      then consider x,y being Element of Fin CR such that
A23:  Sn2ixk1 = x and
A24:  Sn2ixk = y and
A25:  x = {} or x<>{} & y<>{} & PosetMax x <> PosetMax y &
      [PosetMax x,PosetMax y] in IR or
      x<>{} & y<>{} & PosetMax x = PosetMax y &
      [x\{PosetMax x},y\{PosetMax y}] in FinOrd R by Th36;
      per cases by A25;
      suppose x = {};
        hence P[k+1] by A21,A23;
      end;
      suppose
A26:    x<>{} & y<>{} & PosetMax x <> PosetMax y &
        [PosetMax x,PosetMax y] in IR;
        Smax.ixk1 in rng Smax by A11,FUNCT_1:def 3;
        hence P[k+1] by A14,A17,A19,A22,A23,A24,A26,WAYBEL_4:def 25;
      end;
      suppose x<>{} & y<>{} & PosetMax x = PosetMax y &
        [x\{PosetMax x},y\{PosetMax y}] in FinOrd R;
        hence P[k+1] by A17,A19,A22,A23,A24;
      end;
    end;
A27: for k being Nat holds P[k] from NAT_1:sch 2(A15, A16);
A28: now
      let i be Nat;
      assume ix <= i;
      then consider k being Nat such that
A29:  i = ix+k by NAT_1:10;
      reconsider k as Nat;
      i = ix+k by A29;
      hence Smax.i = an by A27;
    end;
A30: now
      let i be Nat such that
A31:  ix <= i;
      reconsider i0=i as Element of NAT by ORDINAL1:def 12;
      consider Sn2i being Element of Fin CR such that
A32:  Sn2i = Sn2.i and Sn2i <> {} and
A33:  Smax.i0 = PosetMax Sn2i by A9;
      take Sn2i;
      thus Sn2i = Sn2.i by A32;
      thus PosetMax Sn2i = an by A28,A31,A33;
    end;
A34: now
      let i be Nat;
      set bnti = bnt.i;
      reconsider bnti as Element of Fin CR;
      take bnti;
      thus bnti = bnt.i;
      set iix = i+ix;
      ex Sn2iix being Element of Fin CR st ( Sn2iix = Sn2.iix)&(
      PosetMax Sn2iix = an) by A30,NAT_1:11;
      hence PosetMax bnti = an by NAT_1:def 3;
    end;
    consider bn being sequence of  FCR such that
A35: for i being Element of NAT holds R[i,bn.i] from FUNCT_2:sch 3(A10);
    reconsider bn as sequence of FinPoset R;
    set Sn1 = [an, bn];
A36: bnt is descending by A4,Th37;
    now
      let i be Nat;
      reconsider i0=i as Element of NAT by ORDINAL1:def 12;
A37:  ex bni being Element of FCR st ( bni = bnt.i0 \ {an})&( bn.i0
      = bni) by A35;
A38:  ex bni1 being Element of FCR st ( bni1 = bnt.(i+1) \ {an})&
      ( bn.(i+1) = bni1) by A35;
      reconsider bnti = bnt.i, bnti1 = bnt.(i+1) as Element of FinPoset R;
      reconsider bnti9=bnti, bnti19=bnti1 as Element of Fin CR;
A39:  bnti1 <> bnti by A36;
      [bnti1, bnti] in FIR by A36;
      then consider x,y being Element of Fin CR such that
A40:  bnti1 = x and
A41:  bnti = y and
A42:  x = {} or x<>{} & y<>{} & PosetMax x <> PosetMax y &
      [PosetMax x,PosetMax y] in the InternalRel of R or
      x<>{} & y<>{} & PosetMax x = PosetMax y &
      [x\{PosetMax x},y\{PosetMax y}] in FinOrd R by Th36;
A43:  now
        let i be Nat;
        bnt.i = Sn2.(i+ix) by NAT_1:def 3;
        hence bnt.i <> {} by A5;
      end;
A44:  now
A45:    ex bnti99 being Element of Fin CR st ( bnti99=bnt.i)&(
        PosetMax bnti99 = an) by A34;
        ex bnti199 being Element of Fin CR st ( bnti199 =bnt.(i+1))
        &( PosetMax bnti199 = an) by A34;
        hence PosetMax bnti9 = an & PosetMax bnti19 = an by A45;
      end;
A46:  bnti9 <> {} by A43;
A47:  bnti19 <> {} by A43;
A48:  an in bnti by A44,A46,Def13;
      an in bnti1 by A44,A47,Def13;
      hence bn.(i+1) <> bn.i by A37,A38,A39,A48,Th1;
      per cases by A42;
      suppose x = {};
        hence [bn.(i+1), bn.i] in FIR by A40,A43;
      end;
      suppose x<>{} & y<>{} & PosetMax x <> PosetMax y &
        [PosetMax x,PosetMax y] in IR;
        hence [bn.(i+1), bn.i] in FIR by A40,A41,A44;
      end;
      suppose x<>{} & y<>{} & PosetMax x = PosetMax y &
        [x\{PosetMax x},y\{PosetMax y}] in FinOrd R;
        hence [bn.(i+1), bn.i] in FIR by A37,A38,A40,A41,A44;
      end;
    end;
    then bn is descending;
    then bn in zz;
    then reconsider Sn1 as Element of Z by ZFMISC_1:def 2;
    take Sn1, Sn2,Smax,an,ix,bnt,bn;
    thus Sn2 = Sn`2;
    thus for i being Nat holds
    ex Sn2i being Element of Fin CR st Sn2i = Sn2.i & Sn2i<>{} &
    Smax.i = PosetMax Sn2i
     proof let i be Nat;
      reconsider i0=i as Element of NAT by ORDINAL1:def 12;
       ex Sn2i being Element of Fin CR st Sn2i = Sn2.i & Sn2i<>{} &
    Smax.i0 = PosetMax Sn2i by A9;
      hence thesis;
     end;
    thus an = MinElement(rng Smax, R);
    thus ix = Smax mindex an;
    thus bnt = Sn2^\ix;
    now
      let i be Nat;
      reconsider i0=i as Element of NAT by ORDINAL1:def 12;
      ex bni being Element of FCR st ( bni = bnt.i0 \ {an})&( bn.i0
      = bni) by A35;
      hence bn.i = bnt.i \ {an};
    end;
    hence for i being Nat holds bn.i = bnt.i \ {an};
    thus for i being Nat st ix <= i holds Smax.i = an by A28;
    thus thesis;
  end;
  set aStart = the Element of R;
  set SS = [aStart, A];
  A in zz by A2;
  then reconsider SS as Element of Z by ZFMISC_1:def 2;
  consider S01 being Element of Z, S02 being sequence of FinPoset R,
  S0max being sequence of  CR, a0 being Element of R,
  i0 being Nat, b0t,b0 being sequence of FinPoset R such that
  S02 = SS`2 and
A49: for i being Nat holds
  ex S02i being Element of Fin CR st S02i = S02.i & S02i <> {} &
  S0max.i = PosetMax S02i and a0 = MinElement(rng S0max, R) and
  i0 = S0max mindex a0 and
A50: b0t = S02^\i0 and
A51: for i being Nat holds b0.i = b0t.i \ {a0} and
A52: for i being Nat st i0 <= i holds S0max.i = a0 and
A53: S01 = [a0,b0] by A3;
  consider S being sequence of Z such that
A54: S.0 = S01 and
A55: for n being Nat holds S[n,S.n,S.(n+1)] from RECDEF_1:sch 2
  (A3);
A56: for n being Nat holds S[n,S.n,S.(n+1)] by A55;
  deffunc F(object) = (S.$1)`1;
A57: now
    let x be object;
    assume x in NAT;
    then reconsider x9=x as Nat;
    reconsider Sx = S.x9 as Element of [:CR, zz:];
    Sx`1 in CR;
    hence F(x) in CR;
  end;
  consider a being sequence of  CR such that
A58: for x being object st x in NAT holds a.x = F(x) from FUNCT_2:sch 2(A57);
  reconsider a as sequence of R;
  defpred PP[Nat] means (for i being Nat holds
  (ex b being sequence of FinPoset R st (b = (S.$1)`2) & (for x being set
  st x in b.i holds x <> (S.$1)`1 & [x, (S.$1)`1] in IR)));
A59: PP[ 0 ]
  proof
    let i be Nat;
    set b = (S.0)`2;
    b in zz;
    then ex z being sequence of FinPoset R st ( z = b)&( z is descending);
    then reconsider b as sequence of FinPoset R;
    take b;
    thus b = (S.0)`2;
    let x be set such that
A60: x in b.i;
    b0 = [a0,b0]`2
      .= b by A53,A54;
    then
A61: x in b0t.i \ {a0} by A51,A60;
    then
A62: x in b0t.i;
    not x in {a0} by A61,XBOOLE_0:def 5;
    hence
A63: x <> (S.0)`1 by A53,A54,TARSKI:def 1;
    b.i c= CR by FINSUB_1:def 5;
    then reconsider x9=x as Element of R by A60;
A64: x in S02.(i+i0) by A50,A62,NAT_1:def 3;
    consider S02ib being Element of Fin CR such that
A65: S02ib = S02.(i+i0) and
A66: S02ib <> {} and
A67: S0max.(i+i0) = PosetMax S02ib by A49;
    PosetMax S02ib = a0 by A52,A67,NAT_1:11;
    then a0 is_maximal_wrt S02ib, IR by A66,Def13;
    then not [a0, x] in IR by A63,A64,A65,A53,A54,WAYBEL_4:def 23;
    then not a0 <= x9 by ORDERS_2:def 5;
    then x9 <= a0 by WAYBEL_0:def 29;
    hence thesis by A53,A54,ORDERS_2:def 5;
  end;
A68: for n being Nat st PP[n] holds PP[n+1]
  proof
    let n be Nat;
    assume PP[n];
    let i be Nat;
    set n1 = n+1;
    reconsider n1 as Nat;
    set b = (S.n1)`2;
    consider Sn2 being sequence of FinPoset R, Smax being sequence of  CR,
    an being Element of R, ix being Nat,
    bnt,bn being sequence of FinPoset R such that
    Sn2 = (S.n)`2 and
A69: for i being Nat holds ex Sn2i being Element of Fin CR
    st Sn2i = Sn2.i & Sn2i <> {} & Smax.i = PosetMax Sn2i
    and an = MinElement(rng Smax, R)
    and ix = Smax mindex an and
A70: bnt = Sn2^\ix and
A71: for i being Nat holds bn.i = bnt.i \ {an} and
A72: for i being Nat st ix <= i holds Smax.i = an and
A73: S.(n+1) = [an,bn] by A56;
    b in zz;
    then ex z being sequence of FinPoset R st ( z = b)&( z is descending);
    then reconsider b as sequence of FinPoset R;
    take b;
    thus b = (S.(n+1))`2;
    let x be set such that
A74: x in b.i;
    bn = [an,bn]`2
     .= b by A73;
    then
A75: x in bnt.i \ {an} by A71,A74;
    then
A76: x in bnt.i;
    not x in {an} by A75,XBOOLE_0:def 5;
    hence
A77: x <> (S.(n+1))`1 by A73,TARSKI:def 1;
    b.i c= CR by FINSUB_1:def 5;
    then reconsider x9=x as Element of R by A74;
A78: x in Sn2.(i+ix) by A70,A76,NAT_1:def 3;
    consider Sn2ib being Element of Fin CR such that
A79: Sn2ib = Sn2.(i+ix) and
A80: Sn2ib <> {} and
A81: Smax.(i+ix) = PosetMax Sn2ib by A69;
    PosetMax Sn2ib = an by A72,A81,NAT_1:11;
    then an is_maximal_wrt Sn2ib, IR by A80,Def13;
    then not [an, x] in IR by A77,A78,A79,A73,WAYBEL_4:def 23;
    then not an <= x9 by ORDERS_2:def 5;
    then x9 <= an by WAYBEL_0:def 29;
    hence thesis by A73,ORDERS_2:def 5;
  end;
A82: for n being Nat holds PP[n] from NAT_1:sch 2(A59, A68);
  defpred P3[Nat] means
  (ex b being sequence of FinPoset R, i being Nat
  st b = (S.$1)`2 & a.($1+1) in b.i);
A83: P3[ 0 ]
  proof
    set b = (S.0)`2;
    b in zz;
    then ex z being sequence of FinPoset R st ( z = b)&( z is descending);
    then reconsider b as sequence of FinPoset R;
    take b;
A84: a.(0 qua Nat+1) = (S.(0 qua Nat+1))`1 by A58;
    consider S12 being sequence of FinPoset R,
    S1max being sequence of  CR, a1 being Element of R,
    i1 being Nat, b1t,b1 being sequence of FinPoset R such that
A85: S12 = (S.0)`2 and
A86: for i being Nat holds
    ex S12i being Element of Fin CR st S12i = S12.i & S12i <> {} &
    S1max.i = PosetMax S12i and
A87: a1 = MinElement(rng S1max, R) and i1 = S1max mindex a1 and
    b1t = S12^\i1 and
    for i being Nat holds b1.i = b1t.i \ {a1}
    and for i being Nat st i1 <= i holds S1max.i = a1 and
A88: S.(0 qua Nat+1) = [a1,b1] by A55;
    rng S1max c= CR by RELAT_1:def 19;
    then a1 in rng S1max by A1,A87,Def17;
    then consider i being object such that
A89: i in dom S1max and
A90: S1max.i = a1 by FUNCT_1:def 3;
A91: ex S12i being Element of Fin CR st ( S12i = S12.i)&( S12i
    <> {})&( S1max.i = PosetMax S12i) by A86,A89;
    reconsider i as Nat by A89;
    take i;
    thus b = (S.0)`2;
A92:   a1 in b.i by A85,A90,A91,Def13;
    thus a.(0 qua Nat+1) in b.i by A84,A88,A92;
  end;
A93: for n being Nat st P3[n] holds P3[n+1]
  proof
    let n being Nat;
    assume P3[n];
    set b = (S.(n+1))`2;
    b in zz;
    then ex z being sequence of FinPoset R st ( z = b)&( z is descending);
    then reconsider b as sequence of FinPoset R;
    take b;
    set n1 = n+1;
    reconsider n1 as Nat;
    consider Sn12 being sequence of FinPoset R,
    Sn1max being sequence of  CR, an1 being Element of R,
    in1 being Nat, bn1t,bn1 being sequence of FinPoset R such that
A94: Sn12 = (S.n1)`2 and
A95: for i being Nat holds
    ex Sn12i being Element of Fin CR st Sn12i = Sn12.i & Sn12i<>{} &
    Sn1max.i = PosetMax Sn12i and
A96: an1 = MinElement(rng Sn1max, R) and in1 = Sn1max mindex an1 and
    bn1t = Sn12^\in1 and
    for i being Nat holds bn1.i = bn1t.i \ {an1}
    and for i being Nat st in1 <= i holds Sn1max.i = an1 and
A97: S.(n1+1) = [an1,bn1] by A55;
    rng Sn1max c= CR by RELAT_1:def 19;
    then an1 in rng Sn1max by A1,A96,Def17;
    then consider i being object such that
A98: i in dom Sn1max and
A99: Sn1max.i = an1 by FUNCT_1:def 3;
A100: ex Sn12i being Element of Fin CR st ( Sn12i = Sn12.i)&(
    Sn12i <> {})&( Sn1max.i = PosetMax Sn12i) by A95,A98;
    reconsider i as Nat by A98;
    take i;
    thus b = (S.(n+1))`2;
A101: an1 in b.i by A94,A99,A100,Def13;
    [an1,bn1]`1 = an1;
    hence thesis by A58,A101,A97;
  end;
A102: for n being Nat holds P3[n] from NAT_1:sch 2(A83, A93);
  defpred P4[Nat] means
  (a.($1+1) <> a.$1 & [a.($1+1), a.$1] in IR);
A103: P4[ 0 ]
  proof
A104: a.0 = (S.0)`1 by A58;
    consider b being sequence of FinPoset R, i being Nat such that
A105: b = (S.0)`2 and
A106: a.(0 qua Nat+1) in b.i by A83;
    ex bb being sequence of FinPoset R st ( bb = (S.0)`2)&( for
    x being set st x in bb.i holds x <> (S.0)`1 & [x, (S.0)`1] in IR) by A59;
    hence a.(0 qua Nat+1) <> a.0 & [a.(0 qua Nat+1), a.0] in IR
    by A104,A105,A106;
  end;
A107: for n being Nat st P4[n] holds P4[n+1]
  proof
    let n be Nat;
    assume that a.(n+1) <> a.(n) and [a.(n+1), a.n] in IR;
A108: a.(n+1) = (S.(n+1))`1 by A58;
    consider b being sequence of FinPoset R, i being Nat such that
A109: b = (S.(n+1))`2 and
A110: a.((n+1)+1) in b.i by A102;
    ex bb being sequence of FinPoset R st ( bb=(S.(n+1))`2)&(
for x being set st x in bb.i holds x <>(S.(n+1))`1 & [x, (S.(n+1)) `1] in IR)
    by A82;
    hence thesis by A108,A109,A110;
  end;
  for n being Nat holds P4[n] from NAT_1:sch 2(A103, A107);
  then a is descending;
  hence contradiction by A1,WELLFND1:14;
end;
