reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for G being Subset of PARTITIONS(Y), A,B,C,D,E,F being a_partition of
Y, z,u being Element of Y, h being Function st G is independent & G={A,B,C,D,E,
F} & A<>B & A<>C & A<>D & A<>E & A<>F & B<>C & B<>D & B<>E & B<>F & C<>D & C<>E
  & C<>F & D<>E & D<>F & E<>F & EqClass(z,C '/\' D '/\' E '/\' F)=EqClass(u,C
  '/\' D '/\' E '/\' F) holds EqClass(u,CompF(A,G)) meets EqClass(z,CompF(B,G))
proof
  let G be Subset of PARTITIONS(Y);
  let A,B,C,D,E,F be a_partition of Y;
  let z,u be Element of Y;
  let h be Function;
  assume that
A1: G is independent and
A2: G={A,B,C,D,E,F} and
A3: A<>B & A<>C & A<>D & A<>E & A<>F & B<>C & B<>D & B<>E & B<>F & C<>D
  & C<>E & C<>F & D<>E & D<>F & E<>F and
A4: EqClass(z,C '/\' D '/\' E '/\' F)=EqClass(u,C '/\' D '/\' E '/\' F);
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
D)) +* (E .--> EqClass(u,E)) +* (F .--> EqClass(u,F)) +* (A .--> EqClass(z,A));
A5: h.A = EqClass(z,A) by A3,Th37;
  set I=EqClass(z,A), GG=EqClass(u,(((B '/\' C) '/\' D) '/\' E '/\' F));
  set H=EqClass(z,CompF(B,G));
A6: A '/\' (C '/\' D '/\' E '/\' F) = A '/\' (C '/\' D '/\' E) '/\' F by
PARTIT1:14
    .= A '/\' (C '/\' D) '/\' E '/\' F by PARTIT1:14
    .= A '/\' C '/\' D '/\' E '/\' F by PARTIT1:14;
  GG = EqClass(u,B '/\' C '/\' D '/\' E) /\ EqClass(u,F) by Th1;
  then GG = EqClass(u,B '/\' C '/\' D) /\ EqClass(u,E) /\ EqClass(u,F) by Th1;
  then
  GG = EqClass(u,B '/\' C) /\ EqClass(u,D) /\ EqClass(u,E) /\ EqClass (u,
  F) by Th1;
  then
A7: GG /\ I = ((((EqClass(u,B) /\ EqClass(u,C)) /\ EqClass(u,D)) /\ EqClass
  (u,E)) /\ EqClass(u,F)) /\ EqClass(z,A) by Th1;
A8: h.B = EqClass(u,B) by A3,Th37;
A9: h.F = EqClass(u,F) by A3,Th37;
A10: h.E = EqClass(u,E) by A3,Th37;
A11: h.D = EqClass(u,D) by A3,Th37;
A12: h.C = EqClass(u,C) by A3,Th37;
A13: rng h = {h.A,h.B,h.C,h.D,h.E,h.F} by Th39;
  rng h c= bool Y
  proof
    let t be object;
    assume
A14: t in rng h;
    now
      per cases by A13,A14,ENUMSET1:def 4;
      case
        t=h.A;
        hence thesis by A5;
      end;
      case
        t=h.B;
        hence thesis by A8;
      end;
      case
        t=h.C;
        hence thesis by A12;
      end;
      case
        t=h.D;
        hence thesis by A11;
      end;
      case
        t=h.E;
        hence thesis by A10;
      end;
      case
        t=h.F;
        hence thesis by A9;
      end;
    end;
    hence thesis;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A15: dom h = G by A2,Th38;
  then A in dom h by A2,ENUMSET1:def 4;
  then
A16: h.A in rng h by FUNCT_1:def 3;
  then
A17: Intersect FF = meet (rng h) by SETFAM_1:def 9;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A18: d in G;
    now
      per cases by A2,A18,ENUMSET1:def 4;
      case
        d=A;
        hence thesis by A5;
      end;
      case
        d=B;
        hence thesis by A8;
      end;
      case
        d=C;
        hence thesis by A12;
      end;
      case
        d=D;
        hence thesis by A11;
      end;
      case
        d=E;
        hence thesis by A10;
      end;
      case
        d=F;
        hence thesis by A9;
      end;
    end;
    hence thesis;
  end;
  then (Intersect FF)<>{} by A1,A15,BVFUNC_2:def 5;
  then consider m being object such that
A19: m in Intersect FF by XBOOLE_0:def 1;
  D in dom h by A2,A15,ENUMSET1:def 4;
  then h.D in rng h by FUNCT_1:def 3;
  then m in h.D by A17,A19,SETFAM_1:def 1;
  then
A20: m in EqClass(u,D) by A3,Th37;
  C in dom h by A2,A15,ENUMSET1:def 4;
  then h.C in rng h by FUNCT_1:def 3;
  then m in h.C by A17,A19,SETFAM_1:def 1;
  then
A21: m in EqClass(u,C) by A3,Th37;
  B in dom h by A2,A15,ENUMSET1:def 4;
  then h.B in rng h by FUNCT_1:def 3;
  then m in h.B by A17,A19,SETFAM_1:def 1;
  then m in EqClass(u,B) by A3,Th37;
  then m in EqClass(u,B) /\ EqClass(u,C) by A21,XBOOLE_0:def 4;
  then
A22: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A20,XBOOLE_0:def 4;
  F in dom h by A2,A15,ENUMSET1:def 4;
  then h.F in rng h by FUNCT_1:def 3;
  then m in h.F by A17,A19,SETFAM_1:def 1;
  then
A23: m in EqClass(u,F) by A3,Th37;
  E in dom h by A2,A15,ENUMSET1:def 4;
  then h.E in rng h by FUNCT_1:def 3;
  then m in h.E by A17,A19,SETFAM_1:def 1;
  then m in EqClass(u,E) by A3,Th37;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) by A22
,XBOOLE_0:def 4;
  then
A24: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) /\
  EqClass(u,F) by A23,XBOOLE_0:def 4;
  m in h.A by A16,A17,A19,SETFAM_1:def 1;
  then m in EqClass(z,A) by A3,Th37;
  then GG /\ I <> {} by A7,A24,XBOOLE_0:def 4;
  then consider p being object such that
A25: p in GG /\ I by XBOOLE_0:def 1;
  reconsider p as Element of Y by A25;
A26: p in GG by A25,XBOOLE_0:def 4;
  set L=EqClass(z,C '/\' D '/\' E '/\' F);
  GG = EqClass(u,(((B '/\' (C '/\' D)) '/\' E) '/\' F)) by PARTIT1:14;
  then GG = EqClass(u,((B '/\' ((C '/\' D) '/\' E)) '/\' F)) by PARTIT1:14;
  then GG = EqClass(u,B '/\' (C '/\' D '/\' E '/\' F)) by PARTIT1:14;
  then
A27: GG c= L by A4,BVFUNC11:3;
A28: z in H by EQREL_1:def 6;
  set K=EqClass(p,C '/\' D '/\' E '/\' F);
  p in K & p in I by A25,EQREL_1:def 6,XBOOLE_0:def 4;
  then
A29: p in I /\ K by XBOOLE_0:def 4;
  then I /\ K in INTERSECTION(A,C '/\' D '/\' E '/\' F) & not I /\ K in {{}}
  by SETFAM_1:def 5,TARSKI:def 1;
  then I /\ K in INTERSECTION(A,C '/\' D '/\' E '/\' F) \ {{}} by
XBOOLE_0:def 5;
  then
A30: I /\ K in A '/\' (C '/\' D '/\' E '/\' F) by PARTIT1:def 4;
  p in EqClass(p,C '/\' D '/\' E '/\' F) by EQREL_1:def 6;
  then K meets L by A27,A26,XBOOLE_0:3;
  then K=L by EQREL_1:41;
  then
A31: z in K by EQREL_1:def 6;
  z in I by EQREL_1:def 6;
  then
A32: z in I /\ K by A31,XBOOLE_0:def 4;
  CompF(B,G) = A '/\' C '/\' D '/\' E '/\' F by A2,A3,Th32;
  then
A33: I /\ K = H or I /\ K misses H by A30,A6,EQREL_1:def 4;
  GG=EqClass(u,CompF(A,G)) by A2,A3,Th31;
  hence thesis by A29,A26,A32,A28,A33,XBOOLE_0:3;
end;
