reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem Th41:
  f is_continuous_on X & X1 c= X implies f is_continuous_on X1
proof
  assume that
A1: f is_continuous_on X and
A2: X1 c= X;
  X c= dom f by A1;
  hence
A3: X1 c= dom f by A2;
  let g;
  assume
A4: g in X1;
  then
A5: f|X is_continuous_in g by A1,A2;
  thus f|X1 is_continuous_in g
  proof
    dom f /\ X1 c= dom f /\ X by A2,XBOOLE_1:26;
    then dom (f|X1) c= dom f /\ X by RELAT_1:61;
    then
A6: dom (f|X1) c= dom (f|X) by RELAT_1:61;
    g in dom f /\ X1 by A3,A4,XBOOLE_0:def 4;
    hence
A7: g in dom (f|X1) by RELAT_1:61;
    then
A8: (f|X)/.g = f/.g by A6,PARTFUN2:15
      .= (f|X1)/.g by A7,PARTFUN2:15;
    let s1 such that
A9: rng s1 c= dom (f|X1) and
A10: s1 is convergent & lim s1 = g;
A11: rng s1 c= dom (f|X) by A9,A6;
A12: now
      let n be Element of NAT;
A13:  s1.n in rng s1 by VALUED_0:28;
      thus ((f|X)/*s1).n = (f|X)/.(s1.n) by A9,A6,FUNCT_2:109,XBOOLE_1:1
        .= f/.(s1.n) by A11,A13,PARTFUN2:15
        .= (f|X1)/.(s1.n) by A9,A13,PARTFUN2:15
        .= ((f|X1)/*s1).n by A9,FUNCT_2:109;
    end;
    (f|X)/*s1 is convergent & (f|X)/.g = lim ((f|X)/*s1) by A5,A10,A11;
    hence thesis by A8,A12,FUNCT_2:63;
  end;
end;
