reserve x for set;
reserve i,j for Integer;
reserve n,n1,n2,n3 for Nat;
reserve p for Prime;
reserve a,b,c,d for Element of GF(p);
reserve K for Ring;
reserve a1,a2,a3,a4,a5,a6 for Element of K;
reserve px,py,pz for object;
reserve Px,Py,Pz for Element of GF(p);
reserve P for Element of ProjCo(GF(p));
reserve O for Element of EC_SetProjCo(a,b,p);

theorem Th41:
  for p be 5_or_greater Prime, z be Element of EC_WParam p,
  P be Element of EC_SetProjCo(z`1,z`2,p)
  holds compell_ProjCo(z,p).(compell_ProjCo(z,p).P) = P
  proof
    let p be 5_or_greater Prime, z be Element of EC_WParam p,
    P be Element of EC_SetProjCo(z`1,z`2,p);
    set Q = compell_ProjCo(z,p).P;
    Q = [P`1_3, -P`2_3, P`3_3] by Def8;
    then A1: Q`1_3 = P`1_3 & Q`2_3 = -P`2_3 & Q`3_3 = P`3_3 by Def3,Def4,Def5;
    set R = compell_ProjCo(z,p).Q;
    R = [Q`1_3, -Q`2_3, Q`3_3] by Def8;
    then R`1_3 = P`1_3 & R`2_3 = -(-P`2_3) & R`3_3 = P`3_3
             by A1,Def3,Def4,Def5;
    then R`1_3 = P`1_3 & R`2_3 = P`2_3 & R`3_3 = P`3_3 by RLVECT_1:17;
    then R = [P`1_3, P`2_3, P`3_3] by Th31;
    hence thesis by Th31;
  end;
