
theorem Th41:
  for x be G_INTEG st
  Re x <> 0 & Im x <> 0 & Re x <> Im x & - Re x <> Im x holds
  not x*' is_associated_to x
  proof
    let x be G_INTEG such that
    A1: Re x <> 0 & Im x <> 0 & Re x <> Im x & - Re x <> Im x;
    assume x*' is_associated_to x;
    then consider d be G_INTEG such that
    A2: d is g_int_unit & x = d* x*' by Th40;
    A3: x*' = Re x+ (- Im x)*<i>;
    now per cases by A2,Th35;
      suppose d = 1;
        then (Im x) = (- Im x) by A2,A3,COMPLEX1:12;
        hence contradiction by A1;
      end;
      suppose d = -1;
        then (Re x) = (Re (-x*')) by A2
        .= - Re (x*') by COMPLEX1:17
        .= - ( Re x) by COMPLEX1:12,A3;
        hence contradiction by A1;
      end;
      suppose d = <i>;
        then (Im x) = Im (<i>*Re x+ (- Im x)*<i>*<i>) by A2
        .= Re x by COMPLEX1:12;
        hence contradiction by A1;
      end;
      suppose d = -<i>;
        then (Im x) = Im (<i>*(-Re x)+ (Im x)*(-1r)) by A2
        .= - Re x by COMPLEX1:12;
        hence contradiction by A1;
      end;
    end;
    hence contradiction;
  end;
