
theorem Th41:
  for G2 being _Graph, V being set, G1 being addLoops of G2, V
  holds G1 is chordal iff G2 is chordal
proof
  let G2 be _Graph, V be set, G1 be addLoops of G2, V;
  hereby
    assume A1: G1 is chordal;
    now
      let P2 be Walk of G2;
      assume A2: P2.length() > 3 & P2 is Cycle-like;
      reconsider P1 = P2 as Walk of G1 by GLIB_006:75;
      A3: P1.length() = P2.length() & P1 is Cycle-like
        by A2, GLIB_006:76, GLIB_001:114;
      now
        consider m, n being odd Nat such that
          A4: m+2 < n & n <= len P1 & P1.m <> P1.n and
          A5: ex e being object st e Joins P1.m,P1.n,G1 and
          A6: for f being object st f in P1.edges()
            holds not f Joins P1.m,P1.n,G1
          by A1, A2, A3, CHORD:def 10, CHORD:def 11;
        take m,n;
        thus m+2 < n & n <= len P2 & P2.m <> P2.n by A4;
        thus ex e being object st e Joins P2.m,P2.n,G2
        proof
          consider e being object such that
            A7: e Joins P1.m,P1.n,G1 by A5;
          take e;
          thus e Joins P2.m,P2.n,G2 by A4, A7, Th17;
        end;
        thus for f being object st f in P2.edges()
          holds not f Joins P2.m,P2.n,G2
        proof
          let f be object;
          assume f in P2.edges();
          then f in P1.edges() by GLIB_001:110;
          then not f Joins P1.m,P1.n,G1 by A6;
          hence not f Joins P2.m,P2.n,G2 by A4, Th17;
        end;
      end;
      hence P2 is chordal by CHORD:def 10;
    end;
    hence G2 is chordal by CHORD:def 11;
  end;
  assume A8: G2 is chordal;
  now
    let P1 be Walk of G1;
    assume A9: P1.length() > 3 & P1 is Cycle-like;
    P1 is Walk of G2
    proof
      assume not P1 is Walk of G2;
      then consider v,e being object such that
        A10: e Joins v,v,G1 & P1 = G1.walkOf(v,e,v) by A9, Th37;
      2*1+1 = len P1 by A10, GLIB_001:14
        .= 2*P1.length()+1 by GLIB_001:112;
      hence contradiction by A9;
    end;
    then reconsider P2 = P1 as Walk of G2;
    A11: P1.length() = P2.length() & P2 is Cycle-like
      by A9, GLIB_006:76, GLIB_001:114;
    now
      consider m, n being odd Nat such that
        A12: m+2 < n & n <= len P2 & P2.m <> P2.n and
        A13: ex e being object st e Joins P2.m,P2.n,G2 and
        A14: for f being object st f in P2.edges()
          holds not f Joins P2.m,P2.n,G2
        by A8, A9, A11, CHORD:def 10, CHORD:def 11;
      take m,n;
      thus m+2 < n & n <= len P1 & P1.m <> P1.n by A12;
      thus ex e being object st e Joins P1.m,P1.n,G1
      proof
        consider e being object such that
          A15: e Joins P2.m,P2.n,G2 by A13;
        take e;
        thus e Joins P1.m,P1.n,G1 by A12, A15, Th17;
      end;
      thus for f being object st f in P1.edges()
        holds not f Joins P1.m,P1.n,G1
      proof
        let f be object;
        assume f in P1.edges();
        then f in P2.edges() by GLIB_001:110;
        then not f Joins P2.m,P2.n,G2 by A14;
        hence not f Joins P1.m,P1.n,G1 by A12, Th17;
      end;
    end;
    hence P1 is chordal by CHORD:def 10;
  end;
  hence thesis by CHORD:def 11;
end;
